Manage Journal Entries limit number of row selection for reversal

[former_member858538]

On app/tile "Manage Journal Entries", is it possible to add a limitation on the number of documents selected for reversal?

This is required by our business. For instance, if a user tries choosing more than 5 documents for reversal, we'd like to issue an error.

We are at S/4HANA 2022 on-premise

Thanks so much!

Simon

[former_member858538]

To avoid a MOD, originally I'd prefer an extension on the UI side, but didn't find one. Finally I ended up with a simple workaround.

Fiori App/Tile: Manage Journal Entries

OData Service: FAC_FINANCIAL_DOCUMENT_SRV_01

Implementation Class: CL_FAC_FIN_DOC_DPC_EXT

Implementation Method: CL_FAC_FIN_DOC_DPC_EXT~ EXECUTE_REVERSE

An Implicit Enhancement:

METHOD execute_reverse.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""$"$\SE:(1) Class CL_FAC_FIN_DOC_DPC_EXT, Method EXECUTE_REVERSE, Start                                                                                       A
*$*$-Start: (1)---------------------------------------------------------------------------------$*$*
ENHANCEMENT 1  ZENHANCE_LIMIT_REVERSE_DOCS_UI.    "active version
   " Enhancement: Limitation on number of reversal documents
   DATA ls_parameter_enh TYPE cl_fac_fin_doc_mpc=>ts_reversedocument.
   io_tech_request_context->get_converted_parameters(
    IMPORTING
      es_parameter_values = ls_parameter_enh ).
   DATA(lt_rev_document_enh) = get_rev_document_list( ls_parameter_enh-accountingdocumentkey ).
   CONSTANTS con_num_of_documents TYPE i VALUE 7. " up to number of documents for reversal
   IF lines( lt_rev_document_enh ) > con_num_of_documents.
     DATA(lt_msg_enh) = VALUE bapiret2_t(
      ( id = 'Z0FI' type = 'E' number = '085' message_v1 = con_num_of_documents )
      ( id = 'Z0FI' type = 'W' number = '086' message_v1 = lines( lt_rev_document_enh ) )
     ).
     " Build a response message container and response back
     DATA(lo_message_container_enh) = mo_context->get_message_container( ).
     lo_message_container_enh->add_messages_from_bapi( it_bapi_messages = lt_msg_enh ).
     RAISE EXCEPTION TYPE /iwbep/cx_mgw_busi_exception
       EXPORTING
         message_container = lo_message_container_enh.
   ENDIF.
ENDENHANCEMENT.
*$*$-End:   (1)---------------------------------------------------------------------------------$*$*

[filipn]

Hello,

There is no simple solution.

Regards,

Filip