You can determine the structure of <itab> at runtime using the cl_abap_typedescr classes.
The following code table an untype data reference and determines its structure at runtime:
Parameter:
@78\QImporting@ ITAB TYPE REF TO DATA
@7B\QReturning@ VALUE( STRUCT ) TYPE EXTDFIEST DD Internal: Information on Table Fields
data: descrref type ref to cl_abap_typedescr,
no_header type c,
structref type ref to cl_abap_structdescr,
tableref type ref to cl_abap_tabledescr,
l_helpid type string,
l_typename type dfies-tabname,
l_compname type dfies-fieldname,
exttab type extdfiest,
extwa type extdfies.
field-symbols: <t> type any,
<f> type any,
<tab> type index table,
<component> type abap_compdescr.
data: ddiccomptab type ddfields,
isddic type abap_bool,
extdfies_wa like line of struct,
b_no_table type c. " flags table is not available
field-symbols <ddiccomp> type dfies.
****Get a pointer to the data table
assign itab->* to <tab>.
***Read the first record initializing a work area and making sure it has some data
read table <tab> index 1 assigning <t>.
if sy-subrc ne 0.
b_no_table = 'X'.
else.
b_no_table = ' '.
endif.
****Get Type Description by Data Reference
tableref ?= cl_abap_typedescr=>describe_by_data_ref( itab ).
try.
****Is the type definition a pointer to a structure?
structref ?= tableref->get_table_line_type( ).
****Is the structure a Data Diction Type?
isddic = structref->is_ddic_type( ).
if isddic eq abap_true.
****Kernel and Dynamic data defintions can't come from the Data Dictionary
if structref->absolute_name+6(2) eq '%_'.
isddic = abap_false.
endif.
endif.
if isddic eq abap_true.
****Definition is in the data Dictionary- We can read details from the returned
****DDic Structure
ddiccomptab = structref->get_ddic_field_list( ).
loop at ddiccomptab assigning <ddiccomp>.
extdfies_wa-fieldname = <ddiccomp>-fieldname.
extdfies_wa-coltitle = <ddiccomp>-reptext.
extdfies_wa-inttype = <ddiccomp>-inttype.
extdfies_wa-convexit = <ddiccomp>-convexit.
append extdfies_wa to struct.
endloop.
else.
if b_no_table is initial.
****Not in DDic - Get a Type description of the Workarea so we can analyse each field
descrref = cl_abap_typedescr=>describe_by_data( <t> ).
try.
****Get the structure of our type description for the workarea
structref ?= descrref.
****Loop through the list of components(fields) in our work area
loop at structref->components assigning <component>.
extdfies_wa-fieldname = <component>-name.
extdfies_wa-coltitle = <component>-name.
****Get a pointer to the individual component(field) that we are currently processing
assign component sy-tabix of structure <t> to <f>.
****Ask for the help ID (F1 help) belonging to field - this will give the Data dictionary
****LIKE reference that this field was created from - See DESCRIBE FIELD - HELP-ID in on-line
****Help for a useful example
describe field <f> help-id l_helpid.
if l_helpid is not initial.
****Split the help-id into structure - element
split l_helpid at '-'
into l_typename l_compname.
extdfies_wa-tabname = l_typename.
*****Get details about the structure or table part of the helpid
call function 'DD_INT_TABLINFO_GET'
exporting
typename = l_typename
tables
extdfies_tab = exttab
exceptions
not_found = 1
internal_error = 2
others = 3.
if sy-subrc eq 0.
****Read the details about the element portion of the help-id from the information
****we just received using the field name from the original component
read table exttab into extwa with key fieldname = extdfies_wa-fieldname.
if sy-subrc eq 0.
extdfies_wa-coltitle = extwa-coltitle.
extdfies_wa-convexit = extwa-convexit.
else.
****No entry for the original component name, try the one from the help-id
read table exttab into extwa with key fieldname = l_compname.
if sy-subrc eq 0.
extdfies_wa-coltitle = extwa-coltitle.
extdfies_wa-convexit = extwa-convexit.
else.
****No Luck so far -> Lets ask the ABAP Descriptor class to try and describe the elment
****using a reference to the component we are processing
data: elemref type ref to cl_abap_elemdescr,
ddicobj type dd_x031l_table.
field-symbols <ddic> type x031l.
****Descriptor for tte Element
descrref = cl_abap_typedescr=>describe_by_data( <f> ).
try.
****Can we cast this to an DDic element descriptor?
elemref ?= descrref.
****Read the DDic defintion for this element
ddicobj = elemref->get_ddic_object( ).
****Get the Conversion Exit recorded in the DDic for this element
read table ddicobj index 1 assigning <ddic>.
if sy-subrc eq 0.
extdfies_wa-convexit = <ddic>-convexit.
endif.
****Catch all Global Execptions - like bad casts
catch cx_root. "#EC CATCH_ALL
"#EC NO_HANDLER
endtry.
endif.
endif.
endif.
endif.
****Use Describe Field on the Element to get its basic data type
describe field <f> type extdfies_wa-inttype.
append extdfies_wa to struct.
endloop.
****Catch all Global Execptions - like bad casts
catch cx_root. "#EC CATCH_ALL
no_header = 'X'.
endtry.
else.
no_header = 'X'.
endif.
endif.
****Catch all Global Execptions - like bad casts
catch cx_root. "#EC CATCH_ALL
no_header = 'X'.
endtry.
You can then process all the fields in your <itab> dynamically with the following code:
*****Loop through the Data Table
loop at <tab> assigning <wa>.
****For each component (field) in the table -Output the data
loop at struct assigning <wa_desc>.
assign component sy-tabix of structure <wa> to <f>.
endloop.
endloop.
- SAP Managed Tags:
