Skip to Content
author's profile photo Former Member
Former Member

F4 Help In Selection screen

Hi Experts,

i have a requirement like , on Selection Screen when user uses the F4 help for an ID Field that ID's description that is visible thorug F4 help should be displayed besides that field.

like parameters p_id type zid,

and I am using F4 help for that , Now I want the description to be displayed onright side of the field.

I know how to do this in Module Pool bt Selection Screen I m not able to.

Please respond.

Thanks in advance.

Add a comment
10|10000 characters needed characters exceeded

Assigned Tags

Related questions

4 Answers

  • Posted on Oct 05, 2010 at 06:10 PM

    Use FM F4IF_INT_TABLE_VALUE_REQUEST

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 05, 2010 at 06:48 PM

    hi,

    Execute this code, make neccessary changes wherever required.

    TYPES:BEGIN OF ty,
          field1 TYPE char01,
          field2 TYPE char05,
          END OF ty.
    
    DATA:it TYPE TABLE OF ty,
         wa TYPE ty,
         i_dyn TYPE TABLE OF dynpread,
         wa_dynn1 TYPE dynpread,
         li_index TYPE sy-tabix,
         lf_prg TYPE d020s-prog,
         lf_dynnr TYPE d020s-dnum,
         i_return TYPE TABLE OF ddshretval,
         wa_return TYPE ddshretval.
    
    SELECTION-SCREEN BEGIN OF LINE.
    PARAMETERS:pa_test TYPE char01,
               pa_desc TYPE char255 MODIF ID ttt.
    SELECTION-SCREEN END OF LINE.
    
    AT SELECTION-SCREEN OUTPUT.
      LOOP AT SCREEN.
        IF screen-group1 = 'TTT'.
          screen-input = 0.
          screen-display_3d = 'X'.
          MODIFY SCREEN.
          EXIT.
        ENDIF.
      ENDLOOP.
    
    AT SELECTION-SCREEN ON VALUE-REQUEST FOR pa_test.
    
      CLEAR it[].
      wa-field1 = 'A'.
      wa-field2 = 'AAAAA'.
      APPEND wa TO it.
      wa-field1 = 'B'.
      wa-field2 = 'BBBBB'.
      APPEND wa TO it.
      CLEAR wa.
    
      CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
        EXPORTING
          retfield    = 'FIELD1'
          dynpprog    = sy-cprog
          dynpnr      = sy-dynnr
          dynprofield = 'PA_TEST'
          value_org   = 'S'
        TABLES
          value_tab   = it[]
          return_tab  = i_return[].
    
    
      READ TABLE i_return INTO wa_return INDEX 1.
      CHECK sy-subrc = 0.
      READ TABLE it INTO wa WITH KEY field1 = wa_return-fieldval.
      CHECK sy-subrc = 0.
      MOVE 'PA_TEST' TO wa_dynn1-fieldname.
      MOVE wa_return-fieldval TO  wa_dynn1-fieldvalue.
        APPEND wa_dynn1 TO i_dyn.
      MOVE 'PA_DESC' TO wa_dynn1-fieldname.
      MOVE wa-field2 TO wa_dynn1-fieldvalue.
      APPEND wa_dynn1 TO i_dyn.
      lf_prg = sy-repid.
      lf_dynnr = sy-dynnr.
    
      CALL FUNCTION 'DYNP_VALUES_UPDATE'
        EXPORTING
          dyname               = lf_prg
          dynumb               = lf_dynnr
        TABLES
          dynpfields           = i_dyn[]
        EXCEPTIONS
          invalid_abapworkarea = 01
          invalid_dynprofield  = 02
          invalid_dynproname   = 03
          invalid_dynpronummer = 04
          invalid_request      = 05
          no_fielddescription  = 06
          undefind_error       = 07.
    

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Oct 05, 2010 at 07:40 PM

    Hi,

    You need to fill the table " VALUE_TAB = it_ID_and_description" with ID and DESCRIPTIONS, before calling the function F4IF_INT_TABLE_VALUE_REQUEST'.

    Good luck.

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Oct 12, 2010 at 06:43 PM

    Thanks ..

    Add a comment
    10|10000 characters needed characters exceeded

Before answering

You should only submit an answer when you are proposing a solution to the poster's problem. If you want the poster to clarify the question or provide more information, please leave a comment instead, requesting additional details. When answering, please include specifics, such as step-by-step instructions, context for the solution, and links to useful resources. Also, please make sure that you answer complies with our Rules of Engagement.
You must be Logged in to submit an answer.

Up to 10 attachments (including images) can be used with a maximum of 1.0 MB each and 10.5 MB total.