Mass activation of Aggregation level

[subramanianselvan]

Dear all..

How to do the mass activation of all Aggregation level in Modeler at one instance. while collection tp we have to activate the individual aggregation level, its more time consuming.

I have lot of aggregation levels to activate, any solutions.

Regards

Perasel

[Former Member · Accepted solution]

Hi there,

Create this program (it was referenced by a SAP note) in se38 transaction:

*&---------------------------------------------------------------------*
*& Report  Z_ACTIVATE_ALVL
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  Z_ACTIVATE_ALVL.


TYPE-POOLS: rs.

PARAMETER: g_iprov TYPE rsinfoprov.

PERFORM run.

*&---------------------------------------------------------------------*
*&      Form  run
*&---------------------------------------------------------------------*
*----------------------------------------------------------------------*
FORM run.

  DATA: l_t_return    TYPE STANDARD TABLE OF bapiret2,
        l_s_return    TYPE bapiret2,
        l_subrc       TYPE sysubrc,
        l_t_alvl      TYPE STANDARD TABLE OF rspls_alvl,
        l_s_alvl      TYPE rspls_alvl,
        l_t_alvl_iobj TYPE STANDARD TABLE OF rspls_s_rfc_alvl_iobj.

  SELECT * FROM rspls_alvl INTO TABLE l_t_alvl
                           WHERE infoprov = g_iprov
                           AND   objvers  = 'A'.
  CHECK l_t_alvl IS NOT INITIAL.

  LOOP AT l_t_alvl INTO l_s_alvl.

    CALL FUNCTION 'RSPLS_ALVL_CHANGE'
      EXPORTING
        i_aggrlevel    = l_s_alvl-aggrlevel
      IMPORTING
        e_subrc        = l_subrc
      TABLES
        i_tk_alvl_iobj = l_t_alvl_iobj
        e_tk_return    = l_t_return.

    CHECK l_subrc = 0.

    CALL FUNCTION 'RSPLS_ALVL_CHECK'
      EXPORTING
        i_aggrlevel = l_s_alvl-aggrlevel
        i_objvers   = rs_c_objvers-active
      IMPORTING
        e_subrc     = l_subrc
      TABLES
        e_tk_return = l_t_return.

    READ TABLE l_t_return INDEX 1 INTO l_s_return.
    CHECK l_subrc <> 0 OR ( sy-subrc = 0 AND l_s_return-type = 'S' ).

    CLEAR l_t_return.

    CALL FUNCTION 'RSPLS_ALVL_ACTIVATE'
      EXPORTING
        i_aggrlevel = l_s_alvl-aggrlevel
      IMPORTING
        e_subrc     = l_subrc
      TABLES
        e_tk_return = l_t_return.

  ENDLOOP.

ENDFORM.                    "run

This will mas activate your aggregation levels built on InfoProvider.

Diogo.

[balajee_sivakumar]

Hi Perasel,

You can also go to the transaction 'rsor' in your backed system and select the aggregation levels you want to activate and then activate them.

Or else if you want to activate all the aggregation levels in one transport package, you can also go the package in the same 'rsor' transaction and then slect the aggregation levels in that package and then activate them.

Thanks & Regards,

Balajee.