Help required for Contact Data Migration

[Former Member]

Hi All,

I'm involved in an assignment of Data Migration.

I need to know how do I upload the marketing attribute set?

I'm aware of the FM CRM_MKTBP_ASSIGN_ATTRIBUT_TAB, but can someone please share with me the usage of the same?

Like, which import parameters would take the different attributes from the upload excel, and other details?

Any help towards this would be appreciated.

TIA.

Regards,

Richa

[Former Member · Accepted solution]

HI,Richa Bhardwaj :

I wrote down a test program for assigning market attributes to a BP .

maybe it's useful for you .

BTW , i advise you to use the function module 'CRM_MKTBP_ASSIGN_ATTRIBUT_TAB',

another function module 'CRM_MKTBP_ASSIGN_ATTRIBUT' can assin the attributes one by one ,but maybe cause the performance issue .

*&---------------------------------------------------------------------*
*& Report  ZTEST_MAINTAIN_BP_MKT
*&
*&---------------------------------------------------------------------*
*& NOTE:
*&      Transaction code : CRMD_PROF_CHAR
*&      Description      :  maintain the attributes
*&      Transaction code : CRMD_PROF_TEMPL
*&      Description      :  maintain the attributes set
*&---------------------------------------------------------------------*

REPORT  ztest_maintain_bp_mkt.
*=======================================================================
*     Defines
*=======================================================================
DATA : ls_partner_guid  TYPE crmt_partner_guid,          "partner guid
   "internal table for partners who will be assigned the attributes
       lt_mkt_bp        TYPE TABLE OF crmt_mktbp_partner_tab,
   " work area for internal table LT_NKT_BP
       ls_mkt_bp        TYPE crmt_mktbp_partner_tab,
   " internale table for attributes
       lt_attributes    TYPE TABLE OF crmt_mktpfchr_attribute_line,
       ls_attributes    TYPE crmt_mktpfchr_attribute_line.

*=======================================================================
*     Defines
*=======================================================================
PARAMETERS : partner TYPE bu_partner ,
              "attribute set
             attr_set TYPE crmt_prof_template DEFAULT 'BP_CUST_CLASS'.



*=======================================================================
*     start-of-selection
*=======================================================================

START-OF-SELECTION .

  IF NOT partner IS INITIAL .
*   convert the partner no
    CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
      EXPORTING
        input  = partner
      IMPORTING
        output = partner.

*   get the partner guid and append to the internal table
    CLEAR ls_partner_guid.
    SELECT SINGLE partner_guid INTO ls_partner_guid
      FROM but000
      WHERE partner = partner .

    CLEAR ls_mkt_bp .
    REFRESH lt_mkt_bp .

    ls_mkt_bp-partner = partner .
    ls_mkt_bp-partner_guid = ls_partner_guid .
    APPEND ls_mkt_bp TO  lt_mkt_bp .

* assign the attributes
    CLEAR ls_attributes.
    REFRESH lt_attributes.
    ls_attributes-atname = 'FREQ'.
    ls_attributes-atvalue = 'B'.
    ls_attributes-single_value = 'X'.
    APPEND ls_attributes TO lt_attributes.

    CLEAR ls_attributes.
    ls_attributes-atname = 'EVENTSTEST'.
    ls_attributes-atvalue = 'VIP_EVENT'.
    ls_attributes-single_value = space.
    APPEND ls_attributes TO lt_attributes.
    CLEAR ls_attributes.
    ls_attributes-atname = 'EVENTSTEST'.
    ls_attributes-atvalue = 'ROAD_SHOW'.
    ls_attributes-single_value = space .
    APPEND ls_attributes TO lt_attributes.

*  assign the attributes to partners
    CALL FUNCTION 'CRM_MKTBP_ASSIGN_ATTRIBUT_TAB'
      EXPORTING
        iv_attribute_set = attr_set
        iv_commit        = 'X'
        iv_obtyp         = 'BUT000'
      TABLES
        it_partner       = lt_mkt_bp
        it_attributes    = lt_attributes.

  ENDIF .

Edited by: xiaoming cai on Dec 22, 2008 4:13 PM

[Former Member]

Hi Richa,

Kindly let me know, how you are migrating the data? (eg: batch load or IDOCs or other media) depending upon that I may help you..

We used IDOCs to migrate the data from legacy systems. We have extended the IDOC to pull the Marketing Attributes from legacy systems. I can let you know - if you are using IDOCs to migrate the data from legacy systems...

Cheers,

Peter J.

[Former Member]

Hi Peter,

I'm writing a report program to upload data that I have in a CSV text file, wherein I have a set of marketing attributes.

Please guide me through the procedure.

TIA.

Regards,

Richa

[Former Member]

Thanks all. The issue got resolved.