HR_ABAP

[Former Member]

Hi to ALL,

iam preparing pay slip in reports,how can i retrive the wage types of ARREARS with respective data element, i am not found the data elements of these wage types.0014 infotype is showing only one field betrg. How can i display the wage types.Plz let me know..it is very urgent.

Thanks in advance

hiddu

Edited by: hiddu hiddu on Jun 26, 2008 9:44 AM

[Former Member]

I'm assuning that you are witting a report to deal with retro payments and wish to report on Payments paid in the period and not for teh period from Payroll REsults PCL2.

This code may help you report from the payroll results. - This is for UK Payroll.

DATA go_prr TYPE REF TO cl_hrpay99_prr_4_pnp_reps.

DATA gt_pernr_pr TYPE h99_hr_pay_result_tab.

DATA go_pernr_pr TYPE REF TO cl_hr_pay_result_gb.

DATA g_retro TYPE h99_add_retroes.

TABLES: pernr,

t512t.

SELECT-OPTIONS r_lgart FOR t512t-lgart.

PARAMETERS: p_inper RADIOBUTTON GROUP g1,

p_frper RADIOBUTTON GROUP g1.

FIELD-SYMBOLS <pernr_pr> TYPE REF TO cl_hr_pay_result.

FIELD-SYMBOLS <wa_rt> TYPE pc207.

FIELD-SYMBOLS <wa_crt> TYPE pc208.

IF NOT p_inper IS INITIAL.

g_retro = 'X'.

ELSE.

g_retro = ' '.

ENDIF.

START-OF-SELECTION.

CALL METHOD cl_hrpay99_prr_4_pnp_reps=>get_instance

EXPORTING

im_pn_begda = pn-begda

im_pn_endda = pn-endda

im_ipview = g_retro

im_molga = '08'

im_add_retroes_to_rgdir = g_retro

IMPORTING

ex_prr = go_prr

EXCEPTIONS

invalid_entries = 1.

IF sy-subrc <> 0.

• MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO

• WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.

ENDIF.

WRITE:/ 'Payroll Results from RT Table'.

skip.

WRITE: / 'Emp No ',

'For Pd',

'In PER',

'S',

'WTs ',

' AMOUNT'.

WRITE: ' RATE'.

WRITE: 'PAY'.

GET pernr.

CALL METHOD go_prr->get_pernr_payr_results_allin1

EXPORTING

im_pernr = pernr-pernr

IMPORTING

ex_pernr_payroll_results = gt_pernr_pr

EXCEPTIONS

OTHERS = 1.

CHECK sy-subrc = 0.

LOOP AT gt_pernr_pr ASSIGNING <pernr_pr>.

go_pernr_pr ?= <pernr_pr>.

LOOP AT go_pernr_pr->inter-rt ASSIGNING <wa_rt>.

CHECK <wa_rt>-lgart IN r_lgart.

CHECK go_pernr_pr->inter-versc-abkrs IN pnpabkrs.

IF NOT p_inper IS INITIAL.

IF go_pernr_pr->period-srtza = 'P'.

<wa_rt>-betrg = <wa_rt>-betrg * -1.

<wa_rt>-betpe = <wa_rt>-betpe * -1.

ENDIF.

WRITE : / pernr-pernr,

go_pernr_pr->period-fpper, go_pernr_pr->period-inper,

go_pernr_pr->period-srtza, <wa_rt>-lgart, <wa_rt>-betrg, <wa_rt>-betpe,

go_pernr_pr->inter-versc-abkrs.

ELSE.

CHECK go_pernr_pr->period-srtza = 'A'.

WRITE : / pernr-pernr,

go_pernr_pr->period-fpper, go_pernr_pr->period-inper,

go_pernr_pr->period-srtza, <wa_rt>-lgart, <wa_rt>-betrg, <wa_rt>-betpe,

go_pernr_pr->inter-versc-abkrs.

ENDIF.

ENDLOOP.

ENDLOOP.

[Former Member]

Thanks a lot for ur help...

hiddu