cancel
Showing results for 
Search instead for 
Did you mean: 

Script logic not generating multple records

Former Member
0 Kudos

*SELECT(%CURR_YR%,[ID],TIME,"[PERIOD] = 'PACYR'")
*SELECT(%EXISTING_INC%,[ID],EMPLOYEE,"[EMPL_STATUS]='Active' AND [MERIT_ELG]<>''")


*XDIM_MEMBERSET TIME=%CURR_YR%
*XDIM_MEMBERSET ACCOUNT=INCREASEMNTH
*XDIM_MEMBERSET WBSE= NO_WBSE
*XDIM_MEMBERSET COMPANY = NO_COMPANY
*XDIM_MEMBERSET COSTCENTER= NO_COSTCENTER
*XDIM_MEMBERSET DATASRC= CNB_INPUT
*XDIM_MEMBERSET EMPLOYEE = %EXISTING_INC%
*XDIM_MEMBERSET PROFITCTR= NO_PROFITCTR
*XDIM_MEMBERSET RPTCURRENCY= USD
*XDIM_MEMBERSET VERSION=2018.PACING01
*XDIM_MEMBERSET WAGETYPE=NO_WAGETYPE
*XDIM_MEMBERSET ROLE=NO_ROLE
*XDIM_MEMBERSET ROLESTATUS=NO_ROLESTATUS

*WHEN EMPLOYEE
*IS %EXISTING_INC%
*REC(EXPRESSION=([COSTCENTER].[NO_COSTCENTER],[COMPANY].[NO_COMPANY],[WAGETYPE].[NO_WAGETYPE],[ROLESTATUS].[NO_ROLESTATUS],[ROLE].[NO_ROLE],[EMPLOYEE].[NO_EMPLOYEE],[PROFITCTR].[NO_PROFITCTR],[DATASRC].[CNB_INPUT],[ACCOUNT].[INCREASEMNTH],[TIME].[2018.INPUT]),ACCOUNT=INCREASEMNTH)
*ENDWHEN
*COMMIT

Result:

CALCULATION BEGIN:

QUERY PROCESSING DATA

QUERY TIME : 0.00 ms. 0 RECORDS QUERIED OUT.

QUERY REFERENCE DATA

QUERY TIME : 0.00 ms. 1 RECORDS QUERIED OUT.

CALCULATION TIME IN TOTAL :0.00 ms.

NO RECORDS GENERATED.

CALCULATION END.

Accepted Solutions (1)

Accepted Solutions (1)

former_member186338
Active Contributor
0 Kudos

Instead of source you are trying to loop empty destination - no records selected - no result!

The best way to copy single value to multiple members is to use *RUNALLOCATION:

SELECT(%CURR_YR%,[ID],TIME,"[PERIOD] = 'PACYR'")
*SELECT(%EXISTING_INC%,[ID],EMPLOYEE,"[EMPL_STATUS]='Active' AND [MERIT_ELG]<>''")

*XDIM_MEMBERSET ACCOUNT=INCREASEMNTH
*XDIM_MEMBERSET WBSE= NO_WBSE
*XDIM_MEMBERSET COMPANY = NO_COMPANY
*XDIM_MEMBERSET COSTCENTER= NO_COSTCENTER
*XDIM_MEMBERSET DATASRC= CNB_INPUT
*XDIM_MEMBERSET EMPLOYEE = %EXISTING_INC%
*XDIM_MEMBERSET PROFITCTR= NO_PROFITCTR
*XDIM_MEMBERSET RPTCURRENCY= USD
*XDIM_MEMBERSET VERSION=2018.PACING01
*XDIM_MEMBERSET WAGETYPE=NO_WAGETYPE
*XDIM_MEMBERSET ROLE=NO_ROLE
*XDIM_MEMBERSET ROLESTATUS=NO_ROLESTATUS

*RUNALLOCATION
*FACTOR=1
*DIM TIME WHAT=2018.INPUT; WHERE=%CURR_YR%; USING=<<<; TOTAL=<<<
*DIM EMPLOYEE WHAT=NO_EMPLOYEE; WHERE=%EXISTING_INC%; USING=<<< TOTAL=<<<
*ENDALLOCATION

Answers (3)

Answers (3)

Former Member
0 Kudos

Hi Valdir,

Thank you so much for your help.

Regards,

Venu

former_member186338
Active Contributor
0 Kudos

Please accept the correct answer!

Former Member
0 Kudos

Hi Vadin,

Thank you for the details.

In my script I am trying to copy NO_EMPLOYEE , meritincrease value to all active employees

(%EXISTING_INC%) .

In debug mode , I am not getting any records generated .And no error msgs.

Please let me know if I am missing anything in the logic. I am trying simple copy to all employees.

former_member186338
Active Contributor
0 Kudos

Sorry, but what do you mean by: "Script logic not generating multple records"???

Please read: https://blogs.sap.com/2014/01/31/how-to-ask-questions-about-script-logic-issues/

And explain everything if you want an answer, including data sample and required calculation logic!