How to get fiscal period based on date and Fiscal year?

[Former Member]

Hi Guys,

Can anybody tell me how to get Fiscal period based on date and Fiscal Year or fiscal year variant?

Thanks,

Gopi.

[Former Member]

CALL FUNCTION 'DATE_TO_PERIOD_CONVERT'

EXPORTING

i_date = sy-datum " today

i_periv = 'FY'

IMPORTING

e_buper = v_period " period

e_gjahr = v_year " year

EXCEPTIONS

input_false = 1

t009_notfound = 2

t009b_notfound = 3

OTHERS = 4.

• create the current period

CONCATENATE v_year v_period INTO v_per_cur.

[former_member194669]

Try with

fm BAPI_COMPANYCODE_GET_PERIOD

a®

[Former Member]

Hi,

Please refer the code below:

*.......................................................................
*: Report:  ZFISCALYR                                                  :
*:                                                                     :
*: Date  :  2004                                                       :
*:                                                                     :
*: Description: Demonstrates how to return the corresponding fiscal    :
*:              year and posting period for a company code and posting :
*:              date or posting date and fiscal year variant.          :
*:.....................................................................:
REPORT  zfiscalyr NO STANDARD PAGE HEADING.

TABLES: ekko.

PARAMETERS:     p_bukrs TYPE ekko-bukrs,
                p_bedat TYPE ekko-bedat.

DATA: gd_fiscalyr  TYPE bapi0002_4-fiscal_year,
      gd_fiscalp   TYPE bapi0002_4-fiscal_period.
DATA: gd_fiscalyr2 TYPE T009B-BDATJ,
      gd_fiscalp2  TYPE bapi0002_4-fiscal_period.

DATA: gd_periv     TYPE t009-periv.

************************************************************************
*START-OF-SELECTION.
START-OF-SELECTION.

* get fiscal year and period - (requires date and company code)
  CALL FUNCTION 'BAPI_COMPANYCODE_GET_PERIOD'
    EXPORTING
      companycodeid = p_bukrs
      posting_date  = p_bedat
    IMPORTING
      fiscal_year   = gd_fiscalyr
      fiscal_period = gd_fiscalp.



* Alternative fiscal year function module
* - (requires date and fiscal year variant code from T009 table)
*--------------------------------------------------------------------

* gets first entry in fiscal year variant table (will need to choose
* correct one from table rather than just using first entry)
  SELECT SINGLE periv
    FROM t009
    INTO gd_periv.

* get fiscal year and period
  CALL FUNCTION 'DETERMINE_PERIOD'
    EXPORTING
      date                      = p_bedat
*    PERIOD_IN                 = '000'
      version                   = gd_periv
   IMPORTING
      period                    = gd_fiscalp2
      year                      = gd_fiscalyr2
   EXCEPTIONS
      period_in_not_valid       = 1
      period_not_assigned       = 2
      version_undefined         = 3
      OTHERS                    = 4.


************************************************************************
*END-OF-SELECTION.
END-OF-SELECTION.
  WRITE:/ 'From function module: BAPI_COMPANYCODE_GET_PERIOD',
        / 'Fiscal year is:', gd_fiscalyr,
        / 'Fiscal period is:', gd_fiscalp.
  SKIP.

  WRITE:/ 'From function module: DETERMINE_PERIOD',
        / 'Fiscal year is:', gd_fiscalyr2,
        / 'Fiscal period is:', gd_fiscalp2.

Thanks,

Sriram Ponna.

Edited by: Sriram Ponna on Apr 17, 2008 8:59 PM