12-04-2007 11:25 AM
Hello Experts . Please give suggestions in changing the below code to increase the performance . Thanks in advance for all your suggestions...
PARAMETERS : Pr_WERKS LIKE EKPO-WERKS OBLIGATORY,
Pr_EINDT LIKE EKET-EINDT OBLIGATORY.
SELECT-OPTIONS : S_LIFNR FOR EKKO-LIFNR MATCHCODE
OBJECT KRED OBLIGATORY.
DATA: BEGIN OF SELEC OCCURS 10,
SIGN(1),
OPTION(2),
LOW LIKE p_eindt,
HIGH LIKE p_eindt,
END OF SELEC.
SELEC-SIGN = 'I'.
SELEC-OPTION = 'BT'.
SELEC-LOW = pr_eindt.
SELEC-HIGH = pr_eindt + 31.
SELECT * FROM EKET WHERE EINDT IN SELEC.
CHECK EKET-MENGE NE 0.
SELECT * FROM EKPO WHERE EBELN = EKET-EBELN AND
EBELP = EKET-EBELP AND
WERKS = Pr_WERKS.
SELECT * FROM EKKO WHERE EBELN = EKET-EBELN AND
LIFNR IN S_LIFNR AND
BSTYP = 'L' AND
FRGKE = 'R'.
SELECT SINGLE * FROM MAKT WHERE MATNR = EKPO-MATNR AND
SPRAS = 'EN'.
SELECT SINGLE * FROM LFA1 WHERE LIFNR = EKKO-LIFNR.
EXTRACT DETAIL.
ENDSELECT.
ENDSELECT.
ENDSELECT.
12-04-2007 11:55 AM
It is not necessary to have triple nested selects. With the INTO clauses it should be possible, to improve it even more either with FOR ALL ENTRIES or JOINs.
SELECT * FROM EKET
WHERE EINDT IN SELEC.
AND MENGE NE '0'.
SELECT * FROM EKPO
WHERE EBELN = EKET-EBELN
AND EBELP = EKET-EBELP
AND WERKS = Pr_WERKS.
SELECT SINGLE * FROM MAKT
WHERE MATNR = EKPO-MATNR
AND SPRAS = 'EN'.
ENDSELECT.
SELECT * FROM EKKO
WHERE EBELN = EKET-EBELN
AND LIFNR IN S_LIFNR
AND BSTYP = 'L'
AND FRGKE = 'R'.
SELECT SINGLE * FROM LFA1
WHERE LIFNR = EKKO-LIFNR.
ENDSELECT.
EXTRACT DETAIL.
ENDSELECT.
Siegfried
12-04-2007 12:06 PM
1.Avoid SELECT END SELECT
2.Avoid SELECT * , fetch required fields only.
3.Write FOR ALL ENTRIES option for next select statements.
4. Before writing FOR ALL ENTRIES , check that internal table is initial or not.
if it helps plz give some good points
Thanks
Siva Kumar
12-04-2007 1:21 PM
Ways of Performance Tuning
1. Selection Criteria
2. Select Statements
Select Queries
SQL Interface
Aggregate Functions
For all Entries
Select Over more than one internal table
Selection Criteria
1. Restrict the data to the selection criteria itself, rather than filtering it out using the ABAP code using CHECK statement.
2. Select with selection list.
SELECT * FROM SBOOK INTO SBOOK_WA.
CHECK: SBOOK_WA-CARRID = 'LH' AND
SBOOK_WA-CONNID = '0400'.
ENDSELECT.
The above code can be much more optimized by the code written below which avoids CHECK, selects with selection list
SELECT CARRID CONNID FLDATE BOOKID FROM SBOOK INTO TABLE T_SBOOK
WHERE SBOOK_WA-CARRID = 'LH' AND
SBOOK_WA-CONNID = '0400'.
Select Statements Select Queries
1. Avoid nested selects
SELECT * FROM EKKO INTO EKKO_WA.
SELECT * FROM EKAN INTO EKAN_WA
WHERE EBELN = EKKO_WA-EBELN.
ENDSELECT.
ENDSELECT.
The above code can be much more optimized by the code written below.
SELECT PF1 PF2 FF3 FF4 INTO TABLE ITAB
FROM EKKO AS P INNER JOIN EKAN AS F
ON PEBELN = FEBELN.
Note: A simple SELECT loop is a single database access whose result is passed to the ABAP program line by line. Nested SELECT loops mean that the number of accesses in the inner loop is multiplied by the number of accesses in the outer loop. One should therefore use nested SELECT loops only if the selection in the outer loop contains very few lines or the outer loop is a SELECT SINGLE statement.
2. Select all the records in a single shot using into table clause of select statement rather than to use Append statements.
SELECT * FROM SBOOK INTO SBOOK_WA.
CHECK: SBOOK_WA-CARRID = 'LH' AND
SBOOK_WA-CONNID = '0400'.
ENDSELECT.
The above code can be much more optimized by the code written below which avoids CHECK, selects with selection list and puts the data in one shot using into table
SELECT CARRID CONNID FLDATE BOOKID FROM SBOOK INTO TABLE T_SBOOK
WHERE SBOOK_WA-CARRID = 'LH' AND
SBOOK_WA-CONNID = '0400'.
3. When a base table has multiple indices, the where clause should be in the order of the index, either a primary or a secondary index.
To choose an index, the optimizer checks the field names specified in the where clause and then uses an index that has the same order of the fields. In certain scenarios, it is advisable to check whether a new index can speed up the performance of a program. This will come handy in programs that access data from the finance tables.
4. For testing existence, use Select.. Up to 1 rows statement instead of a Select-Endselect-loop with an Exit.
SELECT * FROM SBOOK INTO SBOOK_WA
UP TO 1 ROWS
WHERE CARRID = 'LH'.
ENDSELECT.
The above code is more optimized as compared to the code mentioned below for testing existence of a record.
SELECT * FROM SBOOK INTO SBOOK_WA
WHERE CARRID = 'LH'.
EXIT.
ENDSELECT.
5. Use Select Single if all primary key fields are supplied in the Where condition .
If all primary key fields are supplied in the Where conditions you can even use Select Single.
Select Single requires one communication with the database system, whereas Select-Endselect needs two.
Select Statements SQL Interface
1. Use column updates instead of single-row updates
to update your database tables.
SELECT * FROM SFLIGHT INTO SFLIGHT_WA.
SFLIGHT_WA-SEATSOCC =
SFLIGHT_WA-SEATSOCC - 1.
UPDATE SFLIGHT FROM SFLIGHT_WA.
ENDSELECT.
The above mentioned code can be more optimized by using the following code
UPDATE SFLIGHT
SET SEATSOCC = SEATSOCC - 1.
2. For all frequently used Select statements, try to use an index.
SELECT * FROM SBOOK CLIENT SPECIFIED INTO SBOOK_WA
WHERE CARRID = 'LH'
AND CONNID = '0400'.
ENDSELECT.
The above mentioned code can be more optimized by using the following code
SELECT * FROM SBOOK CLIENT SPECIFIED INTO SBOOK_WA
WHERE MANDT IN ( SELECT MANDT FROM T000 )
AND CARRID = 'LH'
AND CONNID = '0400'.
ENDSELECT.
3. Using buffered tables improves the performance considerably.
Bypassing the buffer increases the network considerably
SELECT SINGLE * FROM T100 INTO T100_WA
BYPASSING BUFFER
WHERE SPRSL = 'D'
AND ARBGB = '00'
AND MSGNR = '999'.
The above mentioned code can be more optimized by using the following code
SELECT SINGLE * FROM T100 INTO T100_WA
WHERE SPRSL = 'D'
AND ARBGB = '00'
AND MSGNR = '999'.
Select Statements Aggregate Functions
If you want to find the maximum, minimum, sum and average value or the count of a database column, use a select list with aggregate functions instead of computing the aggregates yourself.
Some of the Aggregate functions allowed in SAP are MAX, MIN, AVG, SUM, COUNT, COUNT( * )
Consider the following extract.
Maxno = 0.
Select * from zflight where airln = LF and cntry = IN.
Check zflight-fligh > maxno.
Maxno = zflight-fligh.
Endselect.
The above mentioned code can be much more optimized by using the following code.
Select max( fligh ) from zflight into maxno where airln = LF and cntry = IN.
Select Statements For All Entries
The for all entries creates a where clause, where all the entries in the driver table are combined with OR. If the number of entries in the driver table is larger than rsdb/max_blocking_factor, several similar SQL statements are executed to limit the length of the WHERE clause.
The plus
Large amount of data
Mixing processing and reading of data
Fast internal reprocessing of data
Fast
The Minus
Difficult to program/understand
Memory could be critical (use FREE or PACKAGE size)
Points to be must considered FOR ALL ENTRIES
Check that data is present in the driver table
Sorting the driver table
Removing duplicates from the driver table
Consider the following piece of extract
Loop at int_cntry.
Select single * from zfligh into int_fligh
where cntry = int_cntry-cntry.
Append int_fligh.
Endloop.
The above mentioned can be more optimized by using the following code.
Sort int_cntry by cntry.
Delete adjacent duplicates from int_cntry.
If NOT int_cntry[] is INITIAL.
Select * from zfligh appending table int_fligh
For all entries in int_cntry
Where cntry = int_cntry-cntry.
Endif.
Select Statements Select Over more than one Internal table
1. Its better to use a views instead of nested Select statements.
SELECT * FROM DD01L INTO DD01L_WA
WHERE DOMNAME LIKE 'CHAR%'
AND AS4LOCAL = 'A'.
SELECT SINGLE * FROM DD01T INTO DD01T_WA
WHERE DOMNAME = DD01L_WA-DOMNAME
AND AS4LOCAL = 'A'
AND AS4VERS = DD01L_WA-AS4VERS
AND DDLANGUAGE = SY-LANGU.
ENDSELECT.
The above code can be more optimized by extracting all the data from view DD01V_WA
SELECT * FROM DD01V INTO DD01V_WA
WHERE DOMNAME LIKE 'CHAR%'
AND DDLANGUAGE = SY-LANGU.
ENDSELECT
2. To read data from several logically connected tables use a join instead of nested Select statements. Joins are preferred only if all the primary key are available in WHERE clause for the tables that are joined. If the primary keys are not provided in join the Joining of tables itself takes time.
SELECT * FROM EKKO INTO EKKO_WA.
SELECT * FROM EKAN INTO EKAN_WA
WHERE EBELN = EKKO_WA-EBELN.
ENDSELECT.
ENDSELECT.
The above code can be much more optimized by the code written below.
SELECT PF1 PF2 FF3 FF4 INTO TABLE ITAB
FROM EKKO AS P INNER JOIN EKAN AS F
ON PEBELN = FEBELN.
3. Instead of using nested Select loops it is often better to use subqueries.
SELECT * FROM SPFLI
INTO TABLE T_SPFLI
WHERE CITYFROM = 'FRANKFURT'
AND CITYTO = 'NEW YORK'.
SELECT * FROM SFLIGHT AS F
INTO SFLIGHT_WA
FOR ALL ENTRIES IN T_SPFLI
WHERE SEATSOCC < F~SEATSMAX
AND CARRID = T_SPFLI-CARRID
AND CONNID = T_SPFLI-CONNID
AND FLDATE BETWEEN '19990101' AND '19990331'.
ENDSELECT.
The above mentioned code can be even more optimized by using subqueries instead of for all entries.
SELECT * FROM SFLIGHT AS F INTO SFLIGHT_WA
WHERE SEATSOCC < F~SEATSMAX
AND EXISTS ( SELECT * FROM SPFLI
WHERE CARRID = F~CARRID
AND CONNID = F~CONNID
AND CITYFROM = 'FRANKFURT'
AND CITYTO = 'NEW YORK' )
AND FLDATE BETWEEN '19990101' AND '19990331'.
ENDSELECT.
1. Table operations should be done using explicit work areas rather than via header lines.
READ TABLE ITAB INTO WA WITH KEY K = 'X BINARY SEARCH.
IS MUCH FASTER THAN USING
READ TABLE ITAB INTO WA WITH KEY K = 'X'.
If TAB has n entries, linear search runs in O( n ) time, whereas binary search takes only O( log2( n ) ).
2. Always try to use binary search instead of linear search. But dont forget to sort your internal table before that.
READ TABLE ITAB INTO WA WITH KEY K = 'X'. IS FASTER THAN USING
READ TABLE ITAB INTO WA WITH KEY (NAME) = 'X'.
3. A dynamic key access is slower than a static one, since the key specification must be evaluated at runtime.
4. A binary search using secondary index takes considerably less time.
5. LOOP ... WHERE is faster than LOOP/CHECK because LOOP ... WHERE evaluates the specified condition internally.
LOOP AT ITAB INTO WA WHERE K = 'X'.
" ...
ENDLOOP.
The above code is much faster than using
LOOP AT ITAB INTO WA.
CHECK WA-K = 'X'.
" ...
ENDLOOP.
6. Modifying selected components using MODIFY itab TRANSPORTING f1 f2.. accelerates the task of updating a line of an internal table.
WA-DATE = SY-DATUM.
MODIFY ITAB FROM WA INDEX 1 TRANSPORTING DATE.
The above code is more optimized as compared to
WA-DATE = SY-DATUM.
MODIFY ITAB FROM WA INDEX 1.
7. Accessing the table entries directly in a "LOOP ... ASSIGNING ..." accelerates the task of updating a set of lines of an internal table considerably
Modifying selected components only makes the program faster as compared to Modifying all lines completely.
e.g,
LOOP AT ITAB ASSIGNING <WA>.
I = SY-TABIX MOD 2.
IF I = 0.
<WA>-FLAG = 'X'.
ENDIF.
ENDLOOP.
The above code works faster as compared to
LOOP AT ITAB INTO WA.
I = SY-TABIX MOD 2.
IF I = 0.
WA-FLAG = 'X'.
MODIFY ITAB FROM WA.
ENDIF.
ENDLOOP.
8. If collect semantics is required, it is always better to use to COLLECT rather than READ BINARY and then ADD.
LOOP AT ITAB1 INTO WA1.
READ TABLE ITAB2 INTO WA2 WITH KEY K = WA1-K BINARY SEARCH.
IF SY-SUBRC = 0.
ADD: WA1-VAL1 TO WA2-VAL1,
WA1-VAL2 TO WA2-VAL2.
MODIFY ITAB2 FROM WA2 INDEX SY-TABIX TRANSPORTING VAL1 VAL2.
ELSE.
INSERT WA1 INTO ITAB2 INDEX SY-TABIX.
ENDIF.
ENDLOOP.
The above code uses BINARY SEARCH for collect semantics. READ BINARY runs in O( log2(n) ) time. The above piece of code can be more optimized by
LOOP AT ITAB1 INTO WA.
COLLECT WA INTO ITAB2.
ENDLOOP.
SORT ITAB2 BY K.
COLLECT, however, uses a hash algorithm and is therefore independent
of the number of entries (i.e. O(1)) .
9. "APPEND LINES OF itab1 TO itab2" accelerates the task of appending a table to another table considerably as compared to LOOP-APPEND-ENDLOOP.
APPEND LINES OF ITAB1 TO ITAB2.
This is more optimized as compared to
LOOP AT ITAB1 INTO WA.
APPEND WA TO ITAB2.
ENDLOOP.
10. DELETE ADJACENT DUPLICATES accelerates the task of deleting duplicate entries considerably as compared to READ-LOOP-DELETE-ENDLOOP.
DELETE ADJACENT DUPLICATES FROM ITAB COMPARING K.
This is much more optimized as compared to
READ TABLE ITAB INDEX 1 INTO PREV_LINE.
LOOP AT ITAB FROM 2 INTO WA.
IF WA = PREV_LINE.
DELETE ITAB.
ELSE.
PREV_LINE = WA.
ENDIF.
ENDLOOP.
11. "DELETE itab FROM ... TO ..." accelerates the task of deleting a sequence of lines considerably as compared to DO -DELETE-ENDDO.
DELETE ITAB FROM 450 TO 550.
This is much more optimized as compared to
DO 101 TIMES.
DELETE ITAB INDEX 450.
ENDDO.
12. Copying internal tables by using ITAB2[ ] = ITAB1[ ] as compared to LOOP-APPEND-ENDLOOP.
ITAB2[] = ITAB1[].
This is much more optimized as compared to
REFRESH ITAB2.
LOOP AT ITAB1 INTO WA.
APPEND WA TO ITAB2.
ENDLOOP.
13. Specify the sort key as restrictively as possible to run the program faster.
SORT ITAB BY K. makes the program runs faster as compared to SORT ITAB.
Internal Tables contd
Hashed and Sorted tables
1. For single read access hashed tables are more optimized as compared to sorted tables.
2. For partial sequential access sorted tables are more optimized as compared to hashed tables
Hashed And Sorted Tables
Point # 1
Consider the following example where HTAB is a hashed table and STAB is a sorted table
DO 250 TIMES.
N = 4 * SY-INDEX.
READ TABLE HTAB INTO WA WITH TABLE KEY K = N.
IF SY-SUBRC = 0.
" ...
ENDIF.
ENDDO.
This runs faster for single read access as compared to the following same code for sorted table
DO 250 TIMES.
N = 4 * SY-INDEX.
READ TABLE STAB INTO WA WITH TABLE KEY K = N.
IF SY-SUBRC = 0.
" ...
ENDIF.
ENDDO.
Point # 2
Similarly for Partial Sequential access the STAB runs faster as compared to HTAB
LOOP AT STAB INTO WA WHERE K = SUBKEY.
" ...
ENDLOOP.
This runs faster as compared to
LOOP AT HTAB INTO WA WHERE K = SUBKEY.
" ...
ENDLOOP.
12-04-2007 9:00 PM
It would have been nice if you had shared the structure of EXTRACT detail because then we could have retrieved only the required fields instead of SELECT *. Never the less try this code and let me know if there was a performance improvement.
TABLES: ekko.
PARAMETERS : pr_werks LIKE ekpo-werks OBLIGATORY,
pr_eindt LIKE eket-eindt OBLIGATORY.
SELECT-OPTIONS: s_lifnr FOR ekko-lifnr MATCHCODE OBJECT kred OBLIGATORY.
RANGES: r_eindt FOR eket-eindt.
DATA: w_eket TYPE eket,
w_ekpo TYPE ekpo,
w_ekko TYPE ekko,
w_makt TYPE makt,
w_lfa1 TYPE lfa1,
w_found(1) TYPE c ,
t_eket TYPE TABLE OF eket,
t_eket_tmp TYPE TABLE OF eket,
t_ekpo TYPE HASHED TABLE OF ekpo
WITH UNIQUE KEY ebeln ebelp,
t_ekpo_tmp TYPE TABLE OF ekpo,
t_ekko TYPE HASHED TABLE OF ekko
WITH UNIQUE KEY ebeln,
t_ekko_tmp TYPE TABLE OF ekko,
t_makt TYPE HASHED TABLE OF makt
WITH UNIQUE KEY matnr,
t_lfa1 TYPE HASHED TABLE OF lfa1
WITH UNIQUE KEY lifnr.
REFRESH r_eindt.
r_eindt-sign = 'I'.
r_eindt-option = 'BT'.
r_eindt-low = pr_eindt.
r_eindt-high = pr_eindt + 31.
APPEND r_eindt.
CLEAR r_eindt.
SELECT *
FROM eket
INTO TABLE t_eket
WHERE eindt IN r_eindt
AND menge NE 0.
IF sy-subrc EQ 0.
SORT t_eket BY ebeln ebelp etenr.
t_eket_tmp[] = t_eket[].
DELETE ADJACENT DUPLICATES FROM t_eket_tmp COMPARING ebeln ebelp.
SELECT *
FROM ekpo
INTO TABLE t_ekpo
FOR ALL ENTRIES IN t_eket_tmp
WHERE ebeln EQ t_eket_tmp-ebeln
AND ebelp EQ t_eket_tmp-ebelp
AND werks EQ pr_werks.
IF sy-subrc EQ 0.
t_ekpo_tmp[] = t_ekpo[].
SORT t_ekpo_tmp BY ebeln.
DELETE ADJACENT DUPLICATES FROM t_ekpo_tmp COMPARING ebeln.
SELECT *
FROM ekko
INTO TABLE t_ekko
FOR ALL ENTRIES IN t_ekpo_tmp
WHERE ebeln EQ t_ekpo_tmp-ebeln
AND bstyp EQ 'L'
AND lifnr IN s_lifnr
AND frgke EQ 'R'.
IF sy-subrc EQ 0.
t_ekko_tmp[] = t_ekko[].
SORT t_ekko_tmp BY lifnr.
DELETE ADJACENT DUPLICATES FROM t_ekko_tmp COMPARING lifnr.
SELECT *
FROM lfa1
INTO TABLE t_lfa1
FOR ALL ENTRIES IN t_ekko_tmp
WHERE lifnr EQ t_ekko_tmp-lifnr.
ENDIF.
t_ekpo_tmp[] = t_ekpo[].
SORT t_ekpo_tmp BY matnr.
DELETE ADJACENT DUPLICATES FROM t_ekpo_tmp COMPARING matnr.
SELECT *
FROM makt
INTO TABLE t_makt
FOR ALL ENTRIES IN t_ekpo_tmp
WHERE matnr EQ t_ekpo_tmp-matnr
AND spras EQ sy-langu.
ENDIF.
LOOP AT t_eket INTO w_eket.
AT NEW ebeln.
READ TABLE t_ekko INTO w_ekko WITH KEY ebeln = w_eket-ebeln.
IF sy-subrc EQ 0.
READ TABLE t_lfa1 INTO w_lfa1 WITH KEY lifnr = w_ekko-lifnr.
IF sy-subrc NE 0.
CLEAR w_lfa1.
ENDIF.
w_found = 'X'.
ELSE.
CLEAR: w_found,
w_ekko .
ENDIF.
ENDAT.
AT NEW ebelp.
READ TABLE t_ekpo INTO w_ekpo WITH KEY ebeln = w_eket-ebeln
ebelp = w_eket-ebelp.
IF sy-subrc EQ 0.
READ TABLE t_makt INTO w_makt WITH KEY matnr = w_ekpo-matnr.
IF sy-subrc NE 0.
CLEAR w_makt.
ENDIF.
ELSE.
CLEAR w_ekpo.
ENDIF.
ENDAT.
CASE w_found.
WHEN 'X'.
* Add code here to populate the extract.
ENDCASE.
ENDLOOP.
ENDIF.
Message was edited by:
Mark Christian