Here ya go boss. You can not pass the structure which is internal defined in your program to the REUSE_ALV_GRID_DISPLAY, this only works of the structured is defined in the ABAP dictionary. If you still want to generate the field cat from your internal structure, then use this below.
report zrich_0001.
tables: bsak.
type-pools: slis.
data: fieldcat type slis_t_fieldcat_alv.
data: repid type syrepid.
selection-screen begin of block b1 with frame title text-010.
parameters : p_bukrs type bsak-bukrs,
p_augdt type bsak-augdt.
selection-screen end of block b1.
* Use DATA instead of TYPE statement and change TYPE to LIKE
* at field level
data : begin of st_bsak ,
bukrs like bsak-bukrs,
lifnr like bsak-lifnr,
augdt like bsak-augdt,
augbl like bsak-augbl,
gjahr like bsak-gjahr,
belnr like bsak-belnr,
budat like bsak-budat,
bldat like bsak-bldat,
hkont like bsak-hkont,
saknr like bsak-saknr,
zlsch like bsak-zlsch,
zlspr like bsak-zlspr,
hbkid like bsak-hbkid,
end of st_bsak.
data it_bsak like bsak occurs 0 with header line.
* I modified your select statement a bit
select bukrs lifnr augdt augbl gjahr belnr
budat bldat hkont saknr zlsch zlspr hbkid
from bsak
into corresponding fields of table it_bsak
up to 10 rows "need to change it to 65000 rows
where bukrs = p_bukrs.
* Use this function to build your field cat based on the structure ST_BSAK
repid = sy-repid.
call function 'REUSE_ALV_FIELDCATALOG_MERGE'
exporting
i_program_name = repid
i_internal_tabname = 'ST_BSAK'
i_inclname = repid
i_bypassing_buffer = 'X'
changing
ct_fieldcat = fieldcat.
* Now pass the field cat.
call function 'REUSE_ALV_GRID_DISPLAY'
exporting
* i_structure_name = 'st_bsak'
i_grid_title = 'SALES ORDER INFO'
it_fieldcat = fieldcat
tables
t_outtab = it_bsak
exceptions
program_error = 1
others = 2.
if sy-subrc <> 0.
message id sy-msgid type sy-msgty number sy-msgno
with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
endif.
Regards,
RIch Heilman
- SAP Managed Tags:
