Skip to Content
author's profile photo Former Member
Former Member

POPUP Internal Table.

Good Morning,

I've build a report with <i>REUSE_ALV_GRID_DISPLAY</i>.

After displaying the result the user can execute another process using a button i've created in the STATUS_GUI of the ALV_GRID.

This process does several things, and one of them should be a popup of data i have in one of my internal tables.

I've searched for some functions that could popup an internal table to the screen (POPUP_WITH_TABLE_DISPLAY_OK, POPUP_WITH_TABLE_DISPLAY, POPUP_WITH_TABLE_DISPLAY_OK, POPUP_SHOW_INTTAB) but the display isn't what i wanted... I want to display a popup like a ALV_GRID or ALV_LIST.

Is there any function that does that? If not, how can i do it?

Best Regards,

Pedro Gaspar

Add a comment
10|10000 characters needed characters exceeded

Assigned Tags

Related questions

8 Answers

  • Best Answer
    Posted on Aug 23, 2006 at 10:35 AM

    Try this FM,

    REUSE_ALV_POPUP_TO_SELECT.

    Cheers

    Badri.

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Aug 23, 2006 at 10:36 AM

    Try the fm: REUSE_ALV_POPUP_TO_SELECT

    Regards,

    ravi

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Aug 23, 2006 at 10:36 AM

    Hello,

    U can try with this FM

    <b>REUSE_ALV_POPUP_TO_SELECT</b>

    If useful reward.

    Vasanth

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Aug 23, 2006 at 10:16 AM

    Hello Pedro,

    Try using the below FM

    HR_DISPLAY_ERROR_LIST

    Reward points if helps.

    Thanks,

    Krishnakumar

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Aug 23, 2006 at 10:33 AM

    Hello Pedro

    I am not aware of a function module that would do exactly what you want. However, I like to propose a simple alternative.

    (1) Call your own popup (CALL SCREEN nnn STARTING AT ... ENDING AT ...).

    (2) Suppress the dialog (define a module SUPPRESS_DIALOG which contain the single statement SUPPRESS DIALOG).

    (3) Call function module REUSE_ALV_GRID_DISPLAY with your itab.

    I haven't tried this yet but I do not see any reason why it should not work. Of course, don't forget to set status and titlebar for your popup.

    Regards

    Uwe

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Aug 23, 2006 at 10:42 AM

    hi ,

    use <b>REUSE_ALV_POPUP_TO_SELECT</b>

    Check out this code ..

    REPORT z_alv_grid_and_popup.
    *---------------------------------------------------------------------*
    * This program is an example with a Grid list and a Popup list        *
    * The Sales Orders are displayed in the first list                    *
    * When a line is selected, the items of the order are displayed in    *
    * a popup list                                                        *
    *---------------------------------------------------------------------*
    * Author : Michel PIOUD                                               *
    * Email : mpioud@yahoo.fr  HomePage : http://www.geocities.com/mpioud *
    *---------------------------------------------------------------------*
    * Macro definition
    DEFINE m_fieldcat.
      add 1 to ls_fieldcat-col_pos.
      ls_fieldcat-fieldname   = &1.
      ls_fieldcat-ref_tabname = &2.
      append ls_fieldcat to lt_fieldcat.
    END-OF-DEFINITION.
    
    TABLES : vbak.                         " Sales Document: Header Data
    
    TYPE-POOLS: slis.                      " ALV Global types
    
    SELECT-OPTIONS :
      s_vkorg FOR vbak-vkorg,              " Sales organization
      s_kunnr FOR vbak-kunnr,              " Sold-to party
      s_vbeln FOR vbak-vbeln.              " Sales document
    
    SELECTION-SCREEN :
      SKIP, BEGIN OF LINE,COMMENT 5(27) v_1 FOR FIELD p_max.    "#EC NEEDED
    PARAMETERS p_max(2) TYPE n DEFAULT '20' OBLIGATORY.
    SELECTION-SCREEN END OF LINE.
    
    DATA:
    * Data displayed in the first list
      BEGIN OF gt_vbak OCCURS 0,
        vkorg LIKE vbak-vkorg,             " Sales organization
        kunnr LIKE vbak-kunnr,             " Sold-to party
        vbeln LIKE vbak-vbeln,             " Sales document
        netwr LIKE vbak-netwr,             " Net Value of the Sales Order
      END OF gt_vbak,
    
    * Data displayed in the popup list
      BEGIN OF gt_vbap OCCURS 0,
        posnr  LIKE vbap-posnr,            " Sales document item
        matnr  LIKE vbap-matnr,            " Material number
        arktx  LIKE vbap-arktx,            " Short text for sales order item
        kwmeng LIKE vbap-kwmeng,           " Order quantity
        netwr  LIKE vbap-netwr,            " Net value of the order item
      END OF gt_vbap.
    
    *---------------------------------------------------------------------*
    INITIALIZATION.
    
      v_1 = 'Maximum of records to read'.
    
    *---------------------------------------------------------------------*
    START-OF-SELECTION.
    
      PERFORM f_read_data_vbak.
    
      PERFORM f_display_data_vbak.
    
    *---------------------------------------------------------------------*
    *      Form  f_read_data_vbak
    *---------------------------------------------------------------------*
    FORM f_read_data_vbak.
    
      SELECT * INTO CORRESPONDING FIELDS OF TABLE gt_vbak
               FROM vbak
                 UP TO p_max ROWS
              WHERE kunnr IN s_kunnr
                AND vbeln IN s_vbeln
                AND vkorg IN s_vkorg.
    
    ENDFORM.                               " F_READ_DATA_VBAK
    *---------------------------------------------------------------------*
    *      Form  f_display_data_vbak
    *---------------------------------------------------------------------*
    FORM f_display_data_vbak.
    
      DATA:
        ls_fieldcat TYPE slis_fieldcat_alv,
        lt_fieldcat TYPE slis_t_fieldcat_alv.
    
    * Build the field catalog
      m_fieldcat 'VKORG' 'VBAK'.
      m_fieldcat 'KUNNR' 'VBAK'.
      m_fieldcat 'VBELN' 'VBAK'.
      m_fieldcat 'NETWR' 'VBAK'.
    
    * Display the first list
      CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
           EXPORTING
                i_callback_program      = sy-cprog
                i_callback_user_command = 'USER_COMMAND'
                it_fieldcat             = lt_fieldcat
           TABLES
                t_outtab                = gt_vbak.
    
    ENDFORM.                               " F_DISPLAY_DATA_VBAK
    *---------------------------------------------------------------------*
    *       FORM USER_COMMAND                                             *
    *---------------------------------------------------------------------*
    FORM user_command USING u_ucomm     LIKE sy-ucomm
                            us_selfield TYPE slis_selfield.     "#EC CALLED
    
      CASE u_ucomm.
        WHEN '&IC1'.
          READ TABLE gt_vbak INDEX us_selfield-tabindex.
          CHECK sy-subrc EQ 0.
          PERFORM f_read_data_vbap.        " Read data from VBAP
          PERFORM f_display_data_vbap.
      ENDCASE.
    
    ENDFORM.                               " USER_COMMAND
    *---------------------------------------------------------------------*
    *      Form  f_read_data_vbap
    *---------------------------------------------------------------------*
    FORM f_read_data_vbap.
    
      SELECT * INTO CORRESPONDING FIELDS OF TABLE gt_vbap
               FROM vbap
              WHERE vbeln = gt_vbak-vbeln.
    
    ENDFORM.                               " F_READ_DATA_VBAP
    *---------------------------------------------------------------------*
    *      Form  f_display_data_vbap
    *---------------------------------------------------------------------*
    FORM f_display_data_vbap.
    
      DATA:
        ls_private  TYPE slis_data_caller_exit,
        ls_fieldcat TYPE slis_fieldcat_alv,
        lt_fieldcat TYPE slis_t_fieldcat_alv.
    
    * Build the field catalog
      m_fieldcat 'POSNR'  'VBAP'.
      m_fieldcat 'MATNR'  'VBAP'.
      m_fieldcat 'ARKTX'  'VBAP'.
      m_fieldcat 'KWMENG' 'VBAP'.
      m_fieldcat 'NETWR'  'VBAP'.
    
      ls_private-columnopt = 'X'.          " Optimize width
    
    * Display items in a POPUP
      CALL FUNCTION <b>'REUSE_ALV_POPUP_TO_SELECT'</b>
           EXPORTING
                i_selection = ' '
                i_tabname   = 'GT_VBAP'
                it_fieldcat = lt_fieldcat
                is_private  = ls_private
           TABLES
                t_outtab    = gt_vbap.
    
    ENDFORM.                               " F_DISPLAY_DATA_VBAP
    **************** END OF PROGRAM Z_ALV_GRID_AND_POPUP ******************

    Regards,

    Santosh

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Aug 23, 2006 at 11:30 AM

    Hello Again to all,

    Thanks for your help, <i>REUSE_ALV_POPUP_TO_SELECT</i> was what i really needed.

    I'm going to give the 10 points "Solved My Problem" to the first person who replied with this function module. Since i can't reward the max to everyone who gave me the info of that FM, i'm going to reward the others with the max i can. It seems fair enough.

    Once again, thanks to everyone. I hope that with time... lots of code and experience i can win some points too and be the same help as you guys are.

    Best Regards,

    Pedro Gaspar

    Add a comment
    10|10000 characters needed characters exceeded

  • author's profile photo Former Member
    Former Member
    Posted on Sep 01, 2006 at 07:22 PM
    Add a comment
    10|10000 characters needed characters exceeded

Before answering

You should only submit an answer when you are proposing a solution to the poster's problem. If you want the poster to clarify the question or provide more information, please leave a comment instead, requesting additional details. When answering, please include specifics, such as step-by-step instructions, context for the solution, and links to useful resources. Also, please make sure that you answer complies with our Rules of Engagement.
You must be Logged in to submit an answer.

Up to 10 attachments (including images) can be used with a maximum of 1.0 MB each and 10.5 MB total.