How to find user exits for a transaction

[Former Member]

Hi friends,

How do we find the user exits taht are being used in a standard transaction like FLB2.

I managed to run the z-program which is available to list all the transaction's user exits. But this liast only the direct exits ... ie ... Call Function 'Exit_SAPL*'

However how do we list the exits which are called through Call Customer-Function '001' or anything else.

Please suggest.

Thanks in advance.

Regards,

Gayathri N

[Former Member]

Hi

Type the transaction : system->status-> <PROG. NAME>

2 open SE37 , type EXIT<PROG NAME> and press F4 to get the list of function exits available.

3. Open CMOD utilities->SAP enhancements

EDIT->All selections

4.type the function module name obtained in step 2, in fields 'component name' in 'additional selections' block. and execute.

5. The displayed list contains the enhancements names for the transaction You were looking for.

6. Create a project in CMOD and the code in default include->activate.

here is the thread which also answers ur question

Rgds,

Prakash

[Former Member]

hi

try this program.....it will list u all the enhancements even BADIs...

*&--------------------------------------------------------------------&*
*& Report  ZPJA_PM002 (V2)                                            &*
*&                                                                    &*
*&--------------------------------------------------------------------&*
*& Text Elements:                                                     &*
*& P_DEVC Show user-exits from development class                      &*
*& P_LIMIT Limit submit program selection                             &*
*& P_FUNC Show function modules                                       &*
*& P_SUBM Show submit programs                                        &*
*& S01    Selection data (TCode takes precedence  over program name)  &*
*&--------------------------------------------------------------------&*
report  zpja_pm002
  no standard page heading
  line-size 158.

*tables: enlfdir.     "Additional Attributes for Function Modules

data: tabix      like sy-tabix,
      w_linnum   type i,
      w_off      type i,
      w_index    like sy-tabix,
      w_include  like trdir-name,
      w_prog     like trdir-name,
      w_incl     like trdir-name,
      w_area     like rs38l-area,
      w_level,
      w_str(50)  type c,
      w_funcname like tfdir-funcname.

constants: c_fmod(40) type c value 'Function modules selected: ',
           c_subm(40) type c value 'Submit programs selected: ',
           c_col1(12) type c value 'Enhanmt Type',
           c_col2(40) type c value 'Enhancement',
           c_col3(30) type c value 'Program/Include',
           c_col4(20) type c value 'Enhancement Name',
           c_col5(40) type c value 'Enhancement Description'.

* Work Areas: ABAP Workbench
data: begin of wa_d010inc.
data: master type d010inc-master.
data: end of wa_d010inc.

data: begin of wa_tfdir.
data: funcname type tfdir-funcname,
      pname    type tfdir-pname,
      include  type tfdir-include.
data: end of wa_tfdir.

data: begin of wa_tadir.
data: devclass type tadir-devclass.
data: end of wa_tadir.

data: begin of wa_tstc.
data: pgmna type tstc-pgmna.
data: end of wa_tstc.

data: begin of wa_tstcp.
data: param type tstcp-param.
data: end of wa_tstcp.

data: begin of wa_enlfdir.
data: area type enlfdir-area.
data: end of wa_enlfdir.

* Work Areas: BADIs
data: begin of wa_sxs_attr.
data: exit_name type sxs_attr-exit_name.
data: end of wa_sxs_attr.

data: begin of wa_sxs_attrt.
data: text type sxs_attrt-text.
data: end of wa_sxs_attrt.


* Work Areas: Enhancements
data: begin of wa_modsap.
data: member type modsap-member.
data: end of wa_modsap.

data: begin of wa_modsapa.
data: name type modsapa-name.
data: end of wa_modsapa.

data: begin of wa_modsapt.
data: modtext type modsapt-modtext.
data: end of wa_modsapt.

* Work Areas: Business Transaction Events
data: begin of wa_tbe01t.
data: text1 type tbe01t-text1.
data: end of wa_tbe01t.

data: begin of wa_tps01t.
data: text1 type tps01t-text1.
data: end of wa_tps01t.

* user-exits
types: begin of t_userexit,
      type(12) type c,
      pname    like trdir-name,
      txt(300),
      level    type c,
      modname(30) type c,
      modtext(40) type c,
end of t_userexit.
data: i_userexit type standard table of t_userexit with header line.

* Function module developmnet classes
types: begin of t_devclass,
      clas   like trdir-clas,
end of t_devclass.
data: i_devclass type standard table of t_devclass with header line.

* Submit programs
types: begin of t_submit,
      pname     like trdir-name,
      level,
      done,
end of t_submit.
data: i_submit type standard table of t_submit with header line.

* Source code
types: begin of t_sourcetab,                        "#EC * (SLIN lügt!)
        line(200),                                  "#EC * (SLIN lügt!)
      end of t_sourcetab.                           "#EC * (SLIN lügt!)
data: sourcetab type standard table of t_sourcetab with header line.
data c_overflow(30000) type c.

* Description of an ABAP/4 source analysis token
data: i_stoken type standard table of stokex with header line.
data wa_stoken like i_stoken.

* Description of an ABAP/4 source analysis statement
data: i_sstmnt type standard table of sstmnt with header line."#EC

* keywords for searching ABAP code
types: begin of t_keywords,
      word(30),
end of t_keywords.
data: keywords type standard table of t_keywords with header line.

* function modules within program
types: begin of t_fmodule,
      name   like rs38l-name,
      pname  like trdir-name,
      pname2 like trdir-name,
      level,
      bapi,
      done,
end of t_fmodule.
data: i_fmodule type standard table of t_fmodule with header line.

*&--------------------------------------------------------------------&*
*& Selection Options                                                  &*
*&--------------------------------------------------------------------&*
selection-screen begin of block selscr1 with frame title text-s01.
parameter: p_pname like trdir-name memory id rid,
           p_tcode like syst-tcode,
           p_limit(4) type n default 100,
           p_devc  like rihea-dy_ofn default ' ',
           p_func  like rihea-dy_ofn default ' ',
           p_subm  like rihea-dy_ofn default ' '.
selection-screen end of block selscr1.

*&--------------------------------------------------------------------&*
*& START-OF-SELECTION                                                 &*
*&--------------------------------------------------------------------&*
start-of-selection.

  if p_pname is initial and p_tcode is initial.
    message e008(hrfpm).  "Make entry on the selection screen
    stop.
  endif.

* ensure P_LIMIT is not zero.
  if p_limit = 0.
    p_limit = 1.
  endif.

  perform data_select.
  perform get_submit_data.
  perform get_fm_data.
  perform get_additional_data.
  perform data_display.

*&--------------------------------------------------------------------&*
*& Form DATA_SELECT                                                   &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form data_select.

* data selection message to sap gui
  call function 'SAPGUI_PROGRESS_INDICATOR'
    destination 'SAPGUI'
    keeping logical unit of work
    exporting
      text                  = 'Get programs/includes'       "#EC NOTEXT
    exceptions
      system_failure
      communication_failure
    .                                                       "#EC *

* determine search words
  keywords-word = 'CALL'.
  append keywords.
  keywords-word = 'FORM'.
  append keywords.
  keywords-word = 'PERFORM'.
  append keywords.
  keywords-word = 'SUBMIT'.
  append keywords.
  keywords-word = 'INCLUDE'.
  append keywords.

  if not p_tcode is initial.
* get program name from TCode
    select single pgmna from tstc into wa_tstc-pgmna
                 where tcode eq p_tcode.
    if not wa_tstc-pgmna is initial.
      p_pname = wa_tstc-pgmna.
* TCode does not include program name, but does have refereve TCode
    else.
      select single param from tstcp into wa_tstcp-param
                   where tcode eq p_tcode.
      if sy-subrc = 0.
        check wa_tstcp-param(1)   = '/'.
        check wa_tstcp-param+1(1) = '*'.
        if wa_tstcp-param ca ' '.
        endif.
        w_off = sy-fdpos + 1.
        subtract 2 from sy-fdpos.
        if sy-fdpos gt 0.
          p_tcode = wa_tstcp-param+2(sy-fdpos).
        endif.
        select single pgmna from tstc into wa_tstc-pgmna
               where tcode eq p_tcode.
        p_pname = wa_tstc-pgmna.
        if sy-subrc <> 0.
          message e110(/saptrx/asc) with 'No program found for: '
p_tcode."#EC NOTEXT
          stop.
        endif.
      else.
        message e110(/saptrx/asc) with 'No program found for: ' p_tcode.
"#EC NOTEXT
        stop.
      endif.

    endif.
  endif.

* Call customer-function aus Program coding
  read report p_pname into sourcetab.
  if sy-subrc > 0.
    message e017(enhancement) with p_pname raising no_program."#EC *
  endif.

  scan abap-source sourcetab tokens     into i_stoken
                             statements into i_sstmnt
                             keywords   from keywords
                             overflow into c_overflow
                             with includes.
*                              WITH ANALYSIS.
  if sy-subrc > 0. "keine/syntakt. falsche Ablauflog./Fehler im Skanner
    message e130(enhancement) raising syntax_error.         "#EC *
  endif.

* check I_STOKEN for entries
  clear w_linnum.
  describe table i_stoken lines w_linnum.
  if w_linnum gt 0.
    w_level = '0'.
    w_prog = ''.
    w_incl = ''.
    perform data_search tables i_stoken using w_level w_prog w_incl.
  endif.

endform.                        "DATA_SELECT

*&--------------------------------------------------------------------&*
*& Form GET_FM_DATA                                                   &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form get_fm_data.

* data selection message to sap gui
  call function 'SAPGUI_PROGRESS_INDICATOR'
    destination 'SAPGUI'
    keeping logical unit of work
    exporting
      text                  = 'Get function module data'    "#EC NOTEXT
    exceptions
      system_failure
      communication_failure
    .                                                       "#EC *

* Function module data
  sort i_fmodule by name.
  delete adjacent duplicates from i_fmodule comparing name.

  loop at i_fmodule where done  ne 'X'.

    clear:   i_stoken, i_sstmnt, sourcetab, wa_tfdir, w_include .
    refresh: i_stoken, i_sstmnt, sourcetab.

    clear wa_tfdir.
    select single funcname pname include from tfdir into wa_tfdir
                            where funcname = i_fmodule-name.
    check sy-subrc = 0.

    call function 'FUNCTION_INCLUDE_SPLIT'
      exporting
        program = wa_tfdir-pname
      importing
        group   = w_area.

    concatenate 'L' w_area 'U' wa_tfdir-include into w_include.
    i_fmodule-pname  = w_include.
    i_fmodule-pname2 = wa_tfdir-pname.
    modify i_fmodule.

    read report i_fmodule-pname into sourcetab.
    if sy-subrc = 0.

      scan abap-source sourcetab tokens     into i_stoken
                                 statements into i_sstmnt
                                 keywords   from keywords
                                 with includes.
      if sy-subrc > 0.
        message e130(enhancement) raising syntax_error.
      endif.

* check i_stoken for entries
      clear w_linnum.
      describe table i_stoken lines w_linnum.
      if w_linnum gt 0.
        w_level = '1'.
        w_prog  = i_fmodule-pname2.
        w_incl =  i_fmodule-pname.
        perform data_search tables i_stoken using w_level w_prog w_incl.
      endif.
    endif.

  endloop.

  if p_devc = 'X'.
    loop at i_fmodule.
      clear: wa_tadir, wa_enlfdir.

      select single area from enlfdir into wa_enlfdir-area
                            where funcname = i_fmodule-name.
      check not wa_enlfdir-area is initial.

      select single devclass into wa_tadir-devclass
                      from tadir where pgmid    = 'R3TR'
                                   and object   = 'FUGR'
                                   and obj_name = wa_enlfdir-area.
      check not wa_tadir-devclass is initial.
      move wa_tadir-devclass to i_devclass-clas.
      append i_devclass.
      i_fmodule-done = 'X'.
      modify i_fmodule.
    endloop.

    sort i_devclass.
    delete adjacent duplicates from i_devclass.
  endif.

endform.                        "GET_FM_DATA

*&--------------------------------------------------------------------&*
*& Form GET_SUBMIT_DATA                                               &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form get_submit_data.

* data selection message to sap gui
  call function 'SAPGUI_PROGRESS_INDICATOR'
    destination 'SAPGUI'
    keeping logical unit of work
    exporting
      text                  = 'Get submit data'             "#EC NOTEXT
    exceptions
      system_failure
      communication_failure
    .                                                       "#EC *

  sort i_submit.
  delete adjacent duplicates from i_submit comparing pname.
  w_level = '0'.

  loop at i_submit where done ne 'X'.

    clear:   i_stoken, i_sstmnt, sourcetab.
    refresh: i_stoken, i_sstmnt, sourcetab.

    read report i_submit-pname into sourcetab.
    if sy-subrc = 0.

      scan abap-source sourcetab tokens     into i_stoken
                                 statements into i_sstmnt
                                 keywords   from keywords
                                 with includes.
      if sy-subrc > 0.
*        message e130(enhancement) raising syntax_error.
        continue.
      endif.

* check i_stoken for entries
      clear w_linnum.
      describe table i_stoken lines w_linnum.
      if w_linnum gt 0.
        w_prog  = i_submit-pname.
        w_incl = ''.
        perform data_search tables i_stoken using w_level w_prog w_incl.
      endif.
    endif.
* restrict number of submit program selected for processing
    describe table i_submit lines w_linnum.
    if w_linnum ge p_limit.
      w_level = '1'.
    endif.
    i_submit-done = 'X'.
    modify i_submit.
  endloop.

endform.                       "GET_SUBMIT_DATA

*&--------------------------------------------------------------------&*
*& Form DATA_SEARCH                                                   &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form data_search tables p_stoken structure stoken
                        using p_level p_prog p_incl.

  loop at p_stoken.

    clear i_userexit.

    tabix = sy-tabix + 1.
    i_userexit-level = p_level.
    if i_userexit-level = '0'.
      if p_incl is initial.
        i_userexit-pname = p_pname.
      else.
        concatenate  p_pname '/' p_incl into i_userexit-pname.
      endif.
    else.
      if p_incl is initial.
        i_userexit-pname = p_prog.
      else.
        concatenate  p_prog '/' p_incl into i_userexit-pname.
      endif.
    endif.

* Include
    if p_stoken-str eq 'INCLUDE'.
      check p_level eq '0'.    " do not perform for function modules
*(2nd pass)
      w_index = sy-tabix + 1.
      read table p_stoken index w_index into wa_stoken.
      check not wa_stoken-str cs 'STRUCTURE'.
      check not wa_stoken-str cs 'SYMBOL'.
      read table i_submit with key pname = wa_stoken-str.
      if sy-subrc <> 0.
        i_submit-pname = wa_stoken-str.
        i_submit-level = p_level.
        append i_submit.
      endif.
    endif.

* Enhancements
    if p_stoken-str eq 'CUSTOMER-FUNCTION'.
      clear w_funcname.
      read table p_stoken index tabix.
      translate p_stoken-str using ''' '.
      condense p_stoken-str.
      if p_prog is initial.
        concatenate 'EXIT' p_pname p_stoken-str into w_funcname
                     separated by '_'.
      else.
        concatenate 'EXIT' p_prog p_stoken-str into w_funcname
               separated by '_'.
      endif.
      select single member from modsap into wa_modsap-member
            where member = w_funcname.
      if sy-subrc = 0.   " check for valid enhancement
        i_userexit-type = 'Enhancement'.
        i_userexit-txt  = w_funcname.
        append i_userexit.
      else.
        clear wa_d010inc.
        select single master into wa_d010inc-master
              from d010inc
                 where include = p_prog.
        concatenate 'EXIT' wa_d010inc-master p_stoken-str into
w_funcname
               separated by '_'.
        i_userexit-type = 'Enhancement'.
        i_userexit-txt  = w_funcname.
      endif.
    endif.

* BADIs
    if p_stoken-str cs 'cl_exithandler='.
      w_index = sy-tabix + 4.
      read table p_stoken index w_index into wa_stoken.
      i_userexit-txt = wa_stoken-str.
      replace all occurrences of '''' in i_userexit-txt with space.
      i_userexit-type = 'BADI'.
      append i_userexit.
    endif.

* Business transaction events
    if p_stoken-str cs 'OPEN_FI_PERFORM'.
      i_userexit-type = 'BusTrEvent'.
      i_userexit-txt = p_stoken-str.
      replace all occurrences of '''' in i_userexit-txt with space.
      i_userexit-modname =  i_userexit-txt+16(8).
      case i_userexit-txt+25(1).
        when 'E'.
          clear wa_tbe01t.
          select single text1 into wa_tbe01t-text1 from tbe01t
                           where event = i_userexit-txt+16(8)
                             and spras = sy-langu.
          if wa_tbe01t-text1 is initial.
            i_userexit-modtext = '<Not active>'.            "#EC NOTEXT
          else.
            i_userexit-modtext = wa_tbe01t-text1.
          endif.
          i_userexit-modname+8 = '/P&S'.                    "#EC NOTEXT
        when 'P'.
          clear wa_tps01t.
          select single text1 into wa_tps01t-text1 from tps01t
                           where procs = i_userexit-txt+16(8)
                             and spras = sy-langu.
          i_userexit-modtext = wa_tps01t-text1.
          i_userexit-modname+8 = '/Process'.
      endcase.

      append i_userexit.
    endif.

* Program exits
    if p_stoken-str cs 'USEREXIT_'.
      i_userexit-type = 'Program Exit'.
      i_userexit-txt = p_stoken-str.
      replace all occurrences of '''' in i_userexit-txt with space.
      append i_userexit.
    endif.

* Submit programs
    if p_stoken-str cs 'SUBMIT'.
      check p_level eq '0'.    " do not perform for function modules
*(2nd pass)
      check not p_stoken-str cs '_'.   " ensure not SUBMIT_XXX
      w_index = sy-tabix + 1.
      read table p_stoken index w_index into wa_stoken.
      check not wa_stoken-str cs '_'.   " ensure not SUBMIT_XXX
      replace all occurrences of '''' in wa_stoken-str with space.
      read table i_submit with key pname = wa_stoken-str.
      if sy-subrc <> 0.
        i_submit-pname = wa_stoken-str.
        i_submit-level = p_level.
        append i_submit.
      endif.
    endif.

* Perform routines (which reference external programs)
    if p_stoken-str cs 'PERFORM'.
      check p_level eq '0'.    " do not perform for function modules
*(2nd pass)
      w_index = sy-tabix + 1.
      read table p_stoken index w_index into wa_stoken.
      if not wa_stoken-ovfl is initial.
        w_off = wa_stoken-off1 + 10.
        w_str = c_overflow+w_off(30).
        find ')' in w_str match offset w_off.
        w_off = w_off + 1.
        wa_stoken-str = w_str(w_off).
      endif.

      check wa_stoken-str cs '('.
      w_off = 0.
      while sy-subrc  = 0.
        if wa_stoken-str+w_off(1) eq '('.
          replace section offset w_off length 1 of wa_stoken-str with ''
.
          replace all occurrences of ')' in wa_stoken-str with space.
          read table i_submit with key pname = wa_stoken-str.
          if sy-subrc <> 0.
            i_submit-pname = wa_stoken-str.
            append i_submit.
          endif.
          exit.
        else.
          replace section offset w_off length 1 of wa_stoken-str with ''
.
          shift wa_stoken-str left deleting leading space.
        endif.
      endwhile.
    endif.

* Function modules
    if p_stoken-str cs 'FUNCTION'.
      clear i_fmodule.
      check p_level eq '0'.    " do not perform for function modules
*(2nd pass)
      w_index = sy-tabix + 1.
      read table p_stoken index w_index into wa_stoken.

**      if wa_stoken-str cs 'WF_'.
*      if wa_stoken-str cs 'IF_'.
*        break-point.
*      endif.

      if wa_stoken-str cs 'BAPI'.
        i_fmodule-bapi = 'X'.
      endif.
      replace first occurrence of '''' in wa_stoken-str with space.
      replace first occurrence of '''' in wa_stoken-str with space.
      if sy-subrc = 4.   " didn't find 2nd quote (ie name truncated)
        clear wa_tfdir.
        concatenate wa_stoken-str '%' into wa_stoken-str.
        select single funcname into wa_tfdir-funcname from tfdir
                     where funcname like wa_stoken-str.
        if sy-subrc = 0.
          i_fmodule-name = wa_tfdir-funcname.
        else.
          continue.
        endif.
      else.
        i_fmodule-name = wa_stoken-str.
      endif.

      i_fmodule-level = p_level.
      append i_fmodule.
    endif.

  endloop.

endform.                        "DATA_SEARCH

*&--------------------------------------------------------------------&*
*& Form GET_ADDITIONAL_DATA                                           &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form get_additional_data.

* data selection message to sap gui
  call function 'SAPGUI_PROGRESS_INDICATOR'
    destination 'SAPGUI'
    keeping logical unit of work
    exporting
      text                  = 'Get additional data'         "#EC NOTEXT
    exceptions
      system_failure
      communication_failure
    .                                                       "#EC *

  loop at i_userexit.
* Enhancement data
    if  i_userexit-type cs 'Enh'.
      clear: wa_modsapa.
      select single name into wa_modsapa-name from modsap
                        where member = i_userexit-txt.
      check sy-subrc = 0.
      i_userexit-modname = wa_modsapa-name.

      clear wa_modsapt.
      select single modtext into wa_modsapt-modtext from modsapt
                        where name = wa_modsapa-name
                                     and sprsl = sy-langu.
      i_userexit-modtext = wa_modsapt-modtext.
    endif.
* BADI data
    if  i_userexit-type eq 'BADI'.
      clear wa_sxs_attr.
      select single exit_name into wa_sxs_attr-exit_name from sxs_attr
                                    where exit_name = i_userexit-txt.
      if sy-subrc = 0.
        i_userexit-modname = i_userexit-txt.
      else.
        i_userexit-modname = 'Dynamic call'.                "#EC NOTEXT
      endif.
      clear wa_sxs_attrt.
      select single text into wa_sxs_attrt-text from sxs_attrt
                                     where exit_name =
wa_sxs_attr-exit_name
                                       and sprsl = sy-langu.
      i_userexit-modtext = wa_sxs_attrt-text.
    endif.

    modify i_userexit.
  endloop.

* get enhancements via program package
  clear wa_tadir.
  select single devclass into wa_tadir-devclass from tadir
                             where pgmid    = 'R3TR'
                               and object   = 'PROG'
                               and obj_name = p_pname.
  if sy-subrc = 0.
    clear: wa_modsapa, wa_modsapt.
    select name from modsapa into wa_modsapa-name
                          where devclass = wa_tadir-devclass.
      select single modtext from modsapt into wa_modsapt-modtext
                          where name = wa_modsapa-name
                            and sprsl = sy-langu.

      read table i_userexit with key modname = wa_modsapa-name.
      if sy-subrc <> 0.
        i_userexit-modtext = wa_modsapt-modtext.
        i_userexit-type = 'Enhancement'.                    "#EC NOTEXT
        i_userexit-modname  = wa_modsapa-name.
        i_userexit-txt = 'Determined from program DevClass'."#EC NOTEXT
        i_userexit-pname = 'Unknown'.                       "#EC NOTEXT
        append i_userexit.
      endif.
    endselect.
  endif.

endform.                        "GET_ADDITIONAL_DATA

*&--------------------------------------------------------------------&*
*& Form DATA_DISPLAY                                                  &*
*&--------------------------------------------------------------------&*
*&                                                                    &*
*&--------------------------------------------------------------------&*
form data_display.

* data selection message to sap gui
  call function 'SAPGUI_PROGRESS_INDICATOR'
    destination 'SAPGUI'
    keeping logical unit of work
    exporting
      text                  = 'Prepare screen for display'  "#EC NOTEXT
    exceptions
      system_failure
      communication_failure
    .                                                       "#EC *

  sort i_userexit by type txt modname.
  delete adjacent duplicates from i_userexit comparing txt modname.

* format headings
  write: 'Enhancements from main program'.                  "#EC NOTEXT
  write: /.
  uline.
  format color col_heading.
  write: /    sy-vline,
         (12) c_col1,                    "Enhanmt Type
              sy-vline,
         (40) c_col2,                    "Enhancement
              sy-vline,
         (30) c_col3,                    "Program/Include
              sy-vline,
         (20) c_col4,                    "Enhancement name
              sy-vline,
         (40) c_col5,                    "Enhancement description
              sy-vline.
  format reset.
  uline.

* format lines
  loop at i_userexit.
* set line colour
    case i_userexit-type.
      when 'Enhancement'.
        format color 3 intensified off.
      when 'BADI'.
        format color 4 intensified off.
      when 'BusTrEvent'.
        format color 5 intensified off.
      when 'Program Exit'.
        format color 6 intensified off.
      when others.
        format reset.
    endcase.
    write: / sy-vline,
             i_userexit-type,
             sy-vline,
             i_userexit-txt(40),
             sy-vline,
             i_userexit-pname(30),
             sy-vline,
             i_userexit-modname(20),
             sy-vline,
             i_userexit-modtext(40),
             sy-vline.

  endloop.
  format reset.
  uline.

* user-exits from development class of function modules
  if p_devc = 'X'.
    write: /.
    write: / 'User-exits from function module development class'."#EC
*NOTEXT
    write: 157''.
    uline (90).
    write: 157''.

    loop at i_devclass.
      clear wa_modsapa.
      select name from modsapa into wa_modsapa
                   where devclass = i_devclass-clas.
     select single name modtext into corresponding fields of wa_modsapt
                                   from modsapt
                                     where name  = wa_modsapa-name
                                       and sprsl = sy-langu.
        format color 3 intensified off.
        write: / sy-vline,
                 (12) 'Enhancement',
                 sy-vline,
                wa_modsapa-name,
                sy-vline,
                wa_modsapt-modtext,
                sy-vline.
      endselect.
    endloop.
    uline (90).
    format reset.
  endif.

  describe table i_fmodule lines w_linnum.
  write: / c_fmod , at 35 w_linnum.                         "#EC NOTEXT
  write: 157''.
  if p_func = 'X'.
* display fuction modules used in program
    uline (38).
    write: 157''.
    loop at i_fmodule.
      write: sy-vline,
             i_fmodule-name,
             sy-vline,
             i_fmodule-bapi,
             sy-vline.
      write: 157''.
    endloop.
    uline (38).
  endif.

  describe table i_submit lines w_linnum.
  write: / c_subm , at 35 w_linnum.                         "#EC NOTEXT
  write: 157''.
  if p_subm = 'X'.
* display submit programs used in program
    uline (44).
    write: 157''.
    loop at i_submit.
      write: sy-vline,
             i_submit-pname,
             sy-vline.
      write: 157''.
    endloop.
    uline (44).
  endif.

* issue message with number of user-exits displayed
  describe table i_userexit lines w_linnum.
  message s697(56) with w_linnum.

endform.                        "DATA_DISPLAY

Reward points if it helps

Regards

Gunjan

[Former Member]

just go in debugger mode.

make breakpoint on text 'call funtion'

and press f8 continiusly untill u got user exit or customer exit ..(Customer-Function '001' )

it is simple way.

[Simha_]

Hi,

This program gives u abut all the user-exits and BADI for a particular transaction..

&----

---

*& Report ZUSEREXIT_FIND *

*& *

&----

---

*& *

*& *

&----

---

REPORT ZUSEREXIT_FIND .

TABLES : TSTC,

TADIR,

MODSAPT,

MODACT,

TRDIR,

TFDIR,

ENLFDIR,

SXS_ATTRT ,

TSTCT.

DATA : JTAB LIKE TADIR OCCURS 0 WITH HEADER LINE.

DATA : FIELD1(30).

DATA : V_DEVCLASS LIKE TADIR-DEVCLASS.

PARAMETERS : P_TCODE LIKE TSTC-TCODE,

P_PGMNA LIKE TSTC-PGMNA .

DATA wa_tadir type tadir.

START-OF-SELECTION.

IF NOT P_TCODE IS INITIAL.

SELECT SINGLE * FROM TSTC WHERE TCODE EQ P_TCODE.

ELSEIF NOT P_PGMNA IS INITIAL.

TSTC-PGMNA = P_PGMNA.

ENDIF.

IF SY-SUBRC EQ 0.

SELECT SINGLE * FROM TADIR

WHERE PGMID = 'R3TR'

AND OBJECT = 'PROG'

AND OBJ_NAME = TSTC-PGMNA.

MOVE : TADIR-DEVCLASS TO V_DEVCLASS.

IF SY-SUBRC NE 0.

SELECT SINGLE * FROM TRDIR

WHERE NAME = TSTC-PGMNA.

IF TRDIR-SUBC EQ 'F'.

SELECT SINGLE * FROM TFDIR

WHERE PNAME = TSTC-PGMNA.

SELECT SINGLE * FROM ENLFDIR

WHERE FUNCNAME = TFDIR-FUNCNAME.

SELECT SINGLE * FROM TADIR

WHERE PGMID = 'R3TR'

AND OBJECT = 'FUGR'

AND OBJ_NAME EQ ENLFDIR-AREA.

MOVE : TADIR-DEVCLASS TO V_DEVCLASS.

ENDIF.

ENDIF.

SELECT * FROM TADIR INTO TABLE JTAB

WHERE PGMID = 'R3TR'

AND OBJECT in ('SMOD', 'SXSD')

AND DEVCLASS = V_DEVCLASS.

SELECT SINGLE * FROM TSTCT

WHERE SPRSL EQ SY-LANGU

AND TCODE EQ P_TCODE.

FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.

WRITE:/(19) 'Transaction Code - ',

20(20) P_TCODE,

45(50) TSTCT-TTEXT.

SKIP.

IF NOT JTAB[] IS INITIAL.

WRITE:/(105) SY-ULINE.

FORMAT COLOR COL_HEADING INTENSIFIED ON.

• Sorting the internal Table

sort jtab by OBJECT.

data : wf_txt(60) type c,

wf_smod type i ,

wf_badi type i ,

wf_object2(30) type C.

clear : wf_smod, wf_badi , wf_object2.

• Get the total SMOD.

LOOP AT JTAB into wa_tadir.

at first.

FORMAT COLOR COL_HEADING INTENSIFIED ON.

WRITE:/1 SY-VLINE,

2 'Enhancement/ Business Add-in',

41 SY-VLINE ,

42 'Description',

105 SY-VLINE.

WRITE:/(105) SY-ULINE.

endat.

clear wf_txt.

at new object.

if wa_tadir-object = 'SMOD'.

wf_object2 = 'Enhancement' .

elseif wa_tadir-object = 'SXSD'.

wf_object2 = ' Business Add-in'.

endif.

FORMAT COLOR COL_GROUP INTENSIFIED ON.

WRITE:/1 SY-VLINE,

2 wf_object2,

105 SY-VLINE.

endat.

case wa_tadir-object.

when 'SMOD'.

wf_smod = wf_smod + 1.

SELECT SINGLE MODTEXT into wf_txt

FROM MODSAPT

WHERE SPRSL = SY-LANGU

AND NAME = wa_tadir-OBJ_NAME.

FORMAT COLOR COL_NORMAL INTENSIFIED OFF.

when 'SXSD'.

• For BADis

wf_badi = wf_badi + 1 .

select single TEXT into wf_txt

from SXS_ATTRT

where sprsl = sy-langu

and EXIT_NAME = wa_tadir-OBJ_NAME.

FORMAT COLOR COL_NORMAL INTENSIFIED ON.

endcase.

WRITE:/1 SY-VLINE,

2 wa_tadir-OBJ_NAME hotspot on,

41 SY-VLINE ,

42 wf_txt,

105 SY-VLINE.

AT END OF object.

write : /(105) sy-ULINE.

ENDAT.

ENDLOOP.

WRITE:/(105) SY-ULINE.

SKIP.

FORMAT COLOR COL_TOTAL INTENSIFIED ON.

WRITE:/ 'No.of Exits:' , wf_smod.

WRITE:/ 'No.of BADis:' , wf_badi.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(105) 'No userexits or BADis exist'.

ENDIF.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(105) 'Transaction does not exist'.

ENDIF.

AT LINE-SELECTION.

data : wf_object type tadir-object.

clear wf_object.

GET CURSOR FIELD FIELD1.

CHECK FIELD1(8) EQ 'WA_TADIR'.

read table jtab with key obj_name = sy-lisel+1(20).

move jtab-object to wf_object.

case wf_object.

when 'SMOD'.

SET PARAMETER ID 'MON' FIELD SY-LISEL+1(10).

CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.

when 'SXSD'.

SET PARAMETER ID 'EXN' FIELD SY-LISEL+1(20).

CALL TRANSACTION 'SE18' AND SKIP FIRST SCREEN.

endcase.

Cheers,

Simha.

[Former Member]

Hi,

There are diffrent ways for finding an user-exit in the system. Some of the ways are:

a) Using transaction SPRO and under each hierarchy, you will get these enhancements and exits.

b)There is a program called as ZUSEREXIT. Run this in SE38 and execute the report by giving the name of the transaction for which you need to find the exit.

c) You can also go to transaction SMOD and press F4 and then find out the exits available for each transaction.

[Former Member]

Hi

Check out the following code:

TABLES : tstc, "SAP Transaction Codes

tadir, "Directory of Repository Objects

modsapt, "SAP Enhancements - Short Texts

modact, "Modifications

trdir, "System table TRDIR

tfdir, "Function Module

enlfdir, "Additional Attributes for Function Modules

tstct. "Transaction Code Texts

&----

---

*& Variables

&----

---

DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.

DATA : field1(30).

DATA : v_devclass LIKE tadir-devclass.

&----

---

*& Selection Screen Parameters

&----

---

SELECTION-SCREEN BEGIN OF BLOCK a01 WITH FRAME TITLE text-001.

SELECTION-SCREEN SKIP.

PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.

SELECTION-SCREEN SKIP.

SELECTION-SCREEN END OF BLOCK a01.

&----

---

*& Start of main program

&----

---

START-OF-SELECTION.

• Validate Transaction Code

SELECT SINGLE * FROM tstc

WHERE tcode EQ p_tcode.

• Find Repository Objects for transaction code

IF sy-subrc EQ 0.

SELECT SINGLE * FROM tadir

WHERE pgmid = 'R3TR'

AND object = 'PROG'

AND obj_name = tstc-pgmna.

MOVE : tadir-devclass TO v_devclass.

IF sy-subrc NE 0.

SELECT SINGLE * FROM trdir

WHERE name = tstc-pgmna.

IF trdir-subc EQ 'F'.

SELECT SINGLE * FROM tfdir

WHERE pname = tstc-pgmna.

SELECT SINGLE * FROM enlfdir

WHERE funcname = tfdir-funcname.

SELECT SINGLE * FROM tadir

WHERE pgmid = 'R3TR'

AND object = 'FUGR'

AND obj_name = enlfdir-area.

MOVE : tadir-devclass TO v_devclass.

ENDIF.

ENDIF.

• Find SAP Modifactions

SELECT * FROM tadir

INTO TABLE jtab

WHERE pgmid = 'R3TR'

AND object = 'SMOD'

AND devclass = v_devclass.

SELECT SINGLE * FROM tstct

WHERE sprsl EQ sy-langu

AND tcode EQ p_tcode.

FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.

WRITE:/(19) 'Transaction Code - ',

20(20) p_tcode,

45(50) tstct-ttext.

SKIP.

IF NOT jtab[] IS INITIAL.

WRITE:/(95) sy-uline.

FORMAT COLOR COL_HEADING INTENSIFIED ON.

WRITE:/1 sy-vline,

2 'Exit Name',

21 sy-vline ,

22 'Description',

95 sy-vline.

WRITE:/(95) sy-uline.

LOOP AT jtab.

SELECT SINGLE * FROM modsapt

WHERE sprsl = sy-langu AND

name = jtab-obj_name.

FORMAT COLOR COL_NORMAL INTENSIFIED OFF.

WRITE:/1 sy-vline,

2 jtab-obj_name HOTSPOT ON,

21 sy-vline ,

22 modsapt-modtext,

95 sy-vline.

ENDLOOP.

WRITE:/(95) sy-uline.

DESCRIBE TABLE jtab.

SKIP.

FORMAT COLOR COL_TOTAL INTENSIFIED ON.

WRITE:/ 'No of Exits:' , sy-tfill.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(95) 'No User Exit exists'.

ENDIF.

ELSE.

FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.

WRITE:/(95) 'Transaction Code Does Not Exist'.

ENDIF.

• Take the user to SMOD for the Exit that was selected.

AT LINE-SELECTION.

GET CURSOR FIELD field1.

CHECK field1(4) EQ 'JTAB'.

SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).

CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.

Regards

Swathi

[Former Member]

hi

to find user exits for particular transaction. for ex va01. go to cmod nad give project name(ex zabc) and

u will find components assignment field , press f4 and that , and in the search dialog box give the name of package (ex VA) and u will get all the exits.

if their is any problem let me know.

bye

[Former Member]

Hi Gayatri,

You can find it from transaction code se84.

In se84 select envir.and then select exit techniques and then select Customer exits and then select Enhancements,there u give ur programs development class, so that you can get the exits associated with that development class.

(OR)

in se37 give EXIT_(PROGRAMNAME)*and then press F4 so that you can get all the exits available to that program