I need to code front end like SE80.

[Former Member]

Hi,

I need to code some thing similar to

SAP SE80 .

(Assume same as SE80 only)

Any body can tell me how to proceed with the

SAP controls.

a. What controls are required.

b. In what sequence i have to call

these controls.

I need some serious answers .

Thanks in advance.

srini.

[abdul_hakim]

if you want same thing like se80 then why dont you copy the se80 program name and alter it according to ur need.

May i know why you need a transaction like se80.y cant you make use of se80 itself..i m sure you wont get a better development enviroinment that ABAP Development Workbench...

Cheers,

Abdul Hakim

[RichHeilman]

I'm hoping that you are not trying to customize SE80, as it is very complex. Anyway SE80 contains a couple different containers. First, there is a docking container. This is the part that is hangin off the left side. Inside this docking container is a spliter container with two custom containers(there also might be a container holding the toolbar) Inside one of the custom containers(on top) is an HTML control. The container below is a tree control.

Regards,

Rich Heilman

[RichHeilman]

Here is a sample program which implements a docking container with a splitter.

report zrich_0001.

data: docking_left     type ref to cl_gui_docking_container,
      dock_sub_cont1   type ref to cl_gui_container,
      dock_sub_cont2   type ref to cl_gui_container,
      alv_bottom       type ref to cl_gui_alv_grid,
      splitter         type ref to cl_gui_splitter_container,
      html_viewer type ref to cl_gui_html_viewer.

parameters: p_check.

at selection-screen output.

  data: it001w type table of t001w with header line.
  data: repid type sy-repid.
  data: url(255).

  repid = sy-repid.

  if docking_left is initial.

* Create the docking and splitter containers
    create object:

         docking_left
                exporting repid     = repid
                          dynnr     = sy-dynnr
                          side      = docking_left->dock_at_left
                          extension = 525,

         splitter
                  exporting parent = docking_left
                            rows    = 2
                             columns = 1.
* Set the splitters.

    call method:

                splitter->set_border
                  exporting border = space,

                splitter->get_container
                  exporting row            = 1
                            column         = 1
                            receiving container = dock_sub_cont1,

                splitter->set_row_height
                  exporting id             = 1
                            height         = '25',

                splitter->get_container
                  exporting row            = 2
                            column         = 1
                            receiving container = dock_sub_cont2.

* HTML control in the first container

    create object html_viewer
            exporting  parent              = dock_sub_cont1
            exceptions cntl_error         = 1
                       cntl_install_error = 2
                       dp_install_error   = 3
                       dp_error           = 4.

    call method:

    html_viewer->load_mime_object
               exporting
                 object_id  = 'HTMLCNTL_TESTHTM2_SAPLOGO'
                 object_url = 'SAPLOGO.GIF'
               importing
                 assigned_url = url
               exceptions object_not_found     = 1
                          dp_error_general     = 2
                          dp_invalid_parameter = 3,

     html_viewer->show_data
         exporting url   = url
         exceptions cntl_error = 1.


* ALV grid in second splitter container.

    select * into corresponding fields of table it001w
                from t001w.

    create object alv_bottom
                  exporting i_parent = dock_sub_cont2.


    call method alv_bottom->set_table_for_first_display
        exporting
             i_structure_name       = 'T001W'
        changing
             it_outtab       = it001w[].


  endif.

Regards,

Rich Heilman

[Former Member]

Hi Rich,

This is helpful answer to me.

At the HTML control where you added IMAGE.

There i need to add the following.

===================================

I needed to add the INPUT FIELD and

a drop down list box .

Is it possible in this splitter container.

Thanks a bunch.

srini.

[RichHeilman]

Yes, in SE80, this field is implemented in a HTML control. I'm not familiar with how to store the HTML page in SAP. But you will need to do it somehow. Check out program saphtml_events_demo for a sample of how to handle the input fields.

Regards,

Rich Heilman

[Former Member]

HI srinivas,

if u want to create a program like se80, then look at standard program SAPMSEU0.

check the standard program for screen painter( RSSCREENPAINTER)... to under stand the use of controls....

Basha