This is the voting thread for the March 2020 SAP Community Coding Challenge. For the challenge details and directions see this blog:
https://blogs.sap.com/2020/02/28/sap-community-coding-challenge-series/
In this Question thread I will post the 7 finalist. Use the answer voting mechanism to choose the one solution you believe should be the overall winner. Remember: this is all for fun and education. We are all winners here because of the great knowledge sharing!
- SAP Managed Tags:
Finalist #1: CL_ABAP_MATCHER Approach
By pawelgrzeskowiak
SPLIT condense( sentence ) AT space INTO TABLE DATA(words).
out->write( |Number of words: { lines( words ) } | ).
LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
DATA(matcher) = NEW cl_abap_matcher(
regex = NEW cl_abap_regex( pattern = '(.)(?!.*\1)' )
text = <word> ).
out->write( |Number of unique characters in the word: { <word> } - { lines( matcher->find_all( ) ) } | ).
ENDLOOP.
- SAP Managed Tags:
Finalist #2: Regex Approach
By: alexander_frank
SPLIT condense( sentence ) AT space INTO TABLE DATA(words).
out->write( |Number of words: { lines( words ) }| ).
LOOP AT words REFERENCE INTO DATA(word).
DATA(unique_chars_in_word) = replace( val = word->* regex = `(.)(?=.*\1)` with = `` occ = 0 ).
out->write( |Number of unique characters in the word: { word->* } - { strlen( unique_chars_in_word ) }| ).
ENDLOOP.
- SAP Managed Tags:
Finalist #3: For/Group By Approach
By: sougata.chatterjee
SPLIT condense( sentence ) AT space INTO TABLE DATA(lt_words).
out->write( |Number of Words: { lines( lt_words ) }| ).
LOOP AT lt_words ASSIGNING FIELD-SYMBOL(<word>).
out->write(
|Number of unique characters in the word: { <word> } - {
lines( VALUE string_table(
FOR GROUPS x OF y
IN VALUE string_table(
FOR i = 0 THEN i + 1
UNTIL i = strlen( <word> ) ( <word>+i(1) ) )
GROUP BY y ( x ) ) ) }| ).
ENDLOOP.
- SAP Managed Tags:
Finalist #4: SELECT DISTINCT Approach
By: dominik.bigl2
SPLIT condense( sentence ) AT | | INTO TABLE DATA(words).
out->write( |Number of words: { lines( words ) } | ).
LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
DATA(characters) = VALUE ABAP_SORTORDER_tab( FOR char = 0 THEN char + 1 UNTIL char = strlen( <word> ) ( name = <word>+char(1) ) ).
SELECT DISTINCT * FROM @characters AS characters INTO TABLE @DATA(unique_characters).
out->write( |Number of unique characters in the word: { <word> } - { lines( unique_characters ) } | ).
ENDLOOP.
- SAP Managed Tags:
- SAP Managed Tags:
Fun solution but EXTREMELY slow, 700 times slower than Finalist #2 ! I thought the solution had to be realistic but in fact the probable winner will be the craziest. ¯\_(ツ)_/¯
CLASS ltc_main DEFINITION
FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS.
PRIVATE SECTION.
DATA sentence TYPE string VALUE `ABАP is excellent `.
METHODS select_from_itab FOR TESTING.
METHODS regex FOR TESTING.
ENDCLASS.
CLASS ltc_main IMPLEMENTATION.
METHOD regex.
DO 3000 TIMES.
SPLIT condense( sentence ) AT space INTO TABLE DATA(words).
DATA(a) = |Number of words: { lines( words ) }|.
LOOP AT words REFERENCE INTO DATA(word).
DATA(unique_chars_in_word) = replace( val = word->* regex = `(.)(?=.*\1)` with = `` occ = 0 ).
DATA(b) = |Number of unique characters in the word: { word->* } - { strlen( unique_chars_in_word ) }|.
ENDLOOP.
ENDDO.
ENDMETHOD.
METHOD select_from_itab.
DO 3000 TIMES.
SPLIT condense( sentence ) AT | | INTO TABLE DATA(words).
DATA(a) = |Number of words: { lines( words ) } |.
LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
DATA(characters) = VALUE abap_sortorder_tab( FOR char = 0 THEN char + 1 UNTIL char = strlen( <word> ) ( name = <word>+char(1) ) ).
SELECT DISTINCT * FROM @characters AS characters INTO TABLE @DATA(unique_characters).
DATA(b) = |Number of unique characters in the word: { <word> } - { lines( unique_characters ) } |.
ENDLOOP.
ENDDO.
ENDMETHOD.
ENDCLASS.- SAP Managed Tags:
Finalist #5: Single Line Solution
By: christian.guenter
out->write( CONV string(
LET sentence = `ABАP is excellent `
match_word_regex = `\w+`
match_duplicate_chars_regex = `(.)(?=.*\1)`
num_of_words = count( val = sentence
regex = match_word_regex )
IN REDUCE #( INIT output = |Number of words: { num_of_words }|
FOR word_index = 1 WHILE word_index <= num_of_words
LET word = match( val = sentence
regex = match_word_regex
occ = word_index )
num_of_unique_chars = numofchar( replace( val = word
regex = match_duplicate_chars_regex
occ = 0
with = space ) )
IN NEXT output = output && |\nNumber of unique characters in word: { word } - { num_of_unique_chars }| ) ) ).
- SAP Managed Tags:
Finalist #6: Sorted Table Discarding Duplicates Approach
By: jacques.nomssi
TYPES sorted_char_table TYPE SORTED TABLE OF string WITH UNIQUE DEFAULT KEY.
DO.
TRY.
DATA(word) = segment( val = sentence index = sy-index space = ` ` ).
DATA(characters) = VALUE string_table( FOR idx = 0 UNTIL idx = numofchar( word ) ( word+idx(1) ) ).
DATA(chars_in_word) = CORRESPONDING sorted_char_table( characters DISCARDING DUPLICATES ).
out->write( |Number of unique characters in the word:{ word } - { lines( chars_in_word ) }| ).
CATCH cx_sy_strg_par_val.
out->write( |Number of words:{ sy-index - 1 }| ).
EXIT.
ENDTRY.
ENDDO.
- SAP Managed Tags:
Finalist #7: Reduce Approach
By: dinumbabu
SPLIT sentence AT ` ` INTO TABLE DATA(words).
DELETE words WHERE table_line IS INITIAL.
out->write( |no of words: { lines( words ) } | ).
LOOP AT words ASSIGNING FIELD-SYMBOL(<word>).
out->write( |Number of unique characters in the word: { <word> } - {
REDUCE i( INIT len = 1
FOR n = 1 WHILE ( n <= strlen( <word> ) - 1 )
NEXT len = len + COND #( WHEN <word>+0(n) CA <word>+n(1) THEN 0 ELSE 1 ) ) } | ).
ENDLOOP.
- SAP Managed Tags:
