Hi Yuvaraj,
when I understand your problem correctly you will have some structures of types you do not know yet and you want to have them in one component table. I wouldn't use INCLUDES because as you already noticed they can have the same component names. So why not making seperate components of those structures and have them in one table?
My idea would look like this:
TABLE components
LINE:
|__ struct1 type <dynamically structure>
|__ struct2 type <dynamically structure>
|__ ...
You can create this table with this coding:
DATA:
lr_structdescr type ref to cl_abap_structdescr,
lt_components type CL_ABAP_STRUCTDESCR=>COMPONENT_TABLE,
ls_component type line of CL_ABAP_STRUCTDESCR=>COMPONENT_TABLE.
DATA:
lr_line type ref to data,
lr_table type ref to data.
FIELD-SYMBOLS:
<comp> type any,
<line> type any,
<table> type any table.
CONSTANTS: lcon_struct1 TYPE string value '<Structure Type 1>',
lcon_struct2 TYPE string value '<Structure Type 2>'.
**********************************************************
* Create line dynamically.
* Create two structure components in one line
lr_structdescr ?= CL_ABAP_STRUCTDESCR=>DESCRIBE_BY_NAME( lcon_struct1 ).
ls_component-name = 'STRUCT1'.
ls_component-type ?= lr_structdescr.
APPEND ls_component TO lt_components.
lr_structdescr ?= CL_ABAP_STRUCTDESCR=>DESCRIBE_BY_NAME( lcon_struct2 ).
ls_component-name = 'STRUCT2'.
ls_component-type ?= lr_structdescr.
APPEND ls_component TO lt_components.
* Create descriptor for line of table.
lr_structdescr = CL_ABAP_STRUCTDESCR=>CREATE( lt_components ).
* Now create data:
CREATE DATA lr_line TYPE HANDLE lr_structdescr.
ASSIGN lr_line->* TO <line>.
CREATE DATA lr_table LIKE TABLE OF <line>.
ASSIGN lr_table->* TO <table>.
*********************************************************
What you now have is a table which has two components (STRUCT1 and STRUCT2). Those components are typed dynamically at runtime.
To fill these table you can Fill the <line> and insert it into the <table> e.g.
*------- Directly fill the data table.
* Either adress the components like this
ASSIGN COMPONENT 'STRUCT1' OF STRUCTURE <line> TO <comp>.
<comp> = <your data line of structure 1>.
* or this
ASSIGN lr_line->('STRUCT2') TO <comp>.
<comp> = <your data line of structure 2>.
INSERT <line> INTO TABLE <table>.
**********************************************************
If you now want, you can export this table into an itab (as my predecessor suggested). The Export doesn't care if this is a static or dynamic structure. It just pushes the data into your itab and tag it with a name.
e.g.:
*------- Using Export
TYPES: "buffer table type
BEGIN OF itab_line,
clustr TYPE int2,
clustd(1000) TYPE x,
END OF itab_line.
DATA:
itab type table of itab_line. "buffer table
EXPORT table FROM <table> TO INTERNAL TABLE itab.
**********************************************************
What you now did is you have the data from the table within the itab.. but serialized.
**********************************************************
Reading the <table> directly without having it exported would look like this:
LOOP AT <table> ASSIGNING <line>.
ASSIGN COMPONENT 'STRUCT1' OF STRUCTURE <line> TO <comp>. " CASTING TYPE <Structure>.
ENDLOOP.
Using your example you can have the struct vseoattrib now in that <comp>. Using the CASTING you could cast it to a known Structure type.
**********************************************************
When you used EXPORT you need to import the data back to work with it. So this wold look like this:
* Read from exported table into data.
CLEAR: <table>.
IMPORT table TO <table> FROM INTERNAL TABLE itab.
Make sure your <table> is assigned to the right data..
That's it! I don't know what you want to do with that table exactly but only to summerize structures that belong together (in one line) and you do not know those structure types yet you can use this solution.
Regards,
Ralf
You must be a registered user to add a comment. If you've already registered, sign in. Otherwise, register and sign in.