records not posting

[Former Member]

Hi

I have system as below

EPM10 NW SP12

I have 6 months actuals in the i/p i have created

I would like to generate 6 months forecast data.

for which

//first month

*XDIM_MEMBERSET S_ENTITY = US

*XDIM_MEMBERSET S_CATEGORY =Forecast

*XDIM_MEMBERSET S_PRODUCT = ProductA

*XDIM_MEMBERSET TIME =2013.12

*XDIM_MEMBERSET S_ACCOUNT = PL120

//*SELECT(%ACCTSET%,"ID",S_ACCOUNT,"IS_ACCT= 'Y'")

//*FOR %ACCT% = PL120

*WHEN S_ACCOUNT

*IS PL120

//[S_ACCOUNT].[#%ACCT%]=

*REC(EXPRESSION = 1/6*(([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-1,2014.01)])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-2,2014.01)])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-3,2014.01)])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-4,2014.01)])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-5,2014.01)])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[TMVL(-6,2014.01)])), S_CATEGORY = Forecast)

//*NEXT

*ENDWHEN

*COMMIT

ujkt

LOG:

FILE:\ROOT\WEBFOLDERS\ENVIRONMENT408 \ADMINAPP\S_Prod_PBF\TEST.LGF

USER:HANAUSER408

APPSET:ENVIRONMENT408

APPLICATION:S_Prod_PBF

[INFO] GET_DIM_LIST(): I_APPL_ID="S_Prod_PBF", #dimensions=7

INPUTCURRENCY,MEASURES,S_ACCOUNT,S_CATEGORY,S_ENTITY,S_PRODUCT,TIME

#dim_memberset=5

S_ENTITY:US,1 in total.

S_CATEGORY:Forecast,1 in total.

S_PRODUCT:ProductA,1 in total.

TIME:2013.12,1 in total.

S_ACCOUNT:PL120,1 in total.

REC :1/6*(([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.12 ])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.11 ])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.10 ])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.09 ])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.08 ])+([S_ACCOUNT].[%ACCT%],[S_CATEGORY].[Actual],[TIME].[ 2013.07 ]))

CALCULATION BEGIN:

QUERY PROCESSING DATA

QUERY TIME : 250.00 ms. 0  RECORDS QUERIED OUT.

QUERY REFERENCE DATA

QUERY TIME : 349.00 ms. 6  RECORDS QUERIED OUT.

CALCULATION TIME IN TOTAL :26.00 ms.

NO RECORDS GENERATED.

CALCULATION END.

SCRIPT RUNNING TIME IN TOTAL:0.88 s.

I made sure there is data in the scope

thanks in advance.

[former_member186338 · Accepted solution]

Hi,

You don't have data in the script scope:

*XDIM_MEMBERSET S_ENTITY = US

*XDIM_MEMBERSET S_CATEGORY =Forecast

*XDIM_MEMBERSET S_PRODUCT = ProductA

*XDIM_MEMBERSET TIME =2013.12

*XDIM_MEMBERSET S_ACCOUNT = PL120

QUERY PROCESSING DATA

QUERY TIME : 250.00 ms. 0  RECORDS QUERIED OUT.

WHEN/ENDWHEN will loop only if there is some data...

If you want to calculate average of 6 months and post it to 2013.12 the script has to loop all months Actual.

B.R. Vadim

[former_member186338 · Accepted solution]

The correct script will be:

*SELECT(%ACCTSET%,"ID",S_ACCOUNT,"IS_ACCT= 'Y'")

*XDIM_MEMBERSET S_ENTITY = US

*XDIM_MEMBERSET S_CATEGORY =Actual

*XDIM_MEMBERSET S_PRODUCT = ProductA

*XDIM_MEMBERSET TIME = TMVL(-1,2014.01),TMVL(-2,2014.01),TMVL(-3,2014.01),TMVL(-4,2014.01),TMVL(-5,2014.01),TMVL(-6,2014.01)

*XDIM_MEMBERSET S_ACCOUNT = %ACCTSET%

*WHEN S_ACCOUNT

*IS *

*REC(EXPRESSION = %VALUE%/6,S_CATEGORY = Forecast,TIME=2013.12)

*ENDWHEN

B.R. Vadim