Skip to Content

Problem with 'REUSE_ALV_GRID_DISPLAY'

Hi 2 all!

When i add <b>bold</b> code to this small program a problem appears. Total and subtotal texts disappear at first display, but when I make "drill-down" it's ok.

What could it be?

REPORT z_demo_alv_sort.
*---------------------------------------------------------------------*
* This program lists orders (VBAK) with sort and sub-total for *
* 'sold-to-party' (KUNNR) and 'Sales organization' (VKORG) *
*---------------------------------------------------------------------*
* Author : Michel PIOUD *
* Email : mpioud@yahoo.fr HomePage : http://www.geocities.com/mpioud *
*---------------------------------------------------------------------*
TABLES : vbak.

TYPE-POOLS: slis. " ALV Global types

SELECT-OPTIONS :
s_vkorg FOR vbak-vkorg, " Sales organization
s_kunnr FOR vbak-kunnr, " Sold-to party
s_vbeln FOR vbak-vbeln. " Sales document

SELECTION-SCREEN :
SKIP, BEGIN OF LINE,COMMENT 5(27) v_1 FOR FIELD p_max.
PARAMETERS p_max(2) TYPE n DEFAULT '40' OBLIGATORY.
SELECTION-SCREEN END OF LINE.

DATA:
BEGIN OF gt_vbak OCCURS 0,
vkorg LIKE vbak-vkorg, " Sales organization
kunnr LIKE vbak-kunnr, " Sold-to party
vbeln LIKE vbak-vbeln, " Sales document
netwr LIKE vbak-netwr, " Net Value of the Sales Order
waerk LIKE vbak-waerk, " Document currency
END OF gt_vbak.

*---------------------------------------------------------------------*
INITIALIZATION.

v_1 = 'Maximum of records to read'.

*---------------------------------------------------------------------*
START-OF-SELECTION.

PERFORM f_read_data.

PERFORM f_display_data.

*---------------------------------------------------------------------*
* Form f_read_data
*---------------------------------------------------------------------*
FORM f_read_data.

SELECT * INTO CORRESPONDING FIELDS OF TABLE gt_vbak
FROM vbak
UP TO p_max ROWS
WHERE kunnr IN s_kunnr
AND vbeln IN s_vbeln
AND vkorg IN s_vkorg.

ENDFORM. " F_READ_DATA
*---------------------------------------------------------------------*
* Form f_display_data
*---------------------------------------------------------------------*
FORM f_display_data.

DEFINE m_fieldcat.
add 1 to ls_fieldcat-col_pos.
ls_fieldcat-fieldname = &1.
ls_fieldcat-ref_tabname = 'VBAK'.
ls_fieldcat-do_sum = &2.
ls_fieldcat-cfieldname = &3.
<b>ls_fieldcat-tech = &4.</b>
append ls_fieldcat to lt_fieldcat.
END-OF-DEFINITION.

DEFINE m_sort.
add 1 to ls_sort-spos.
ls_sort-fieldname = &1.
ls_sort-up = 'X'.
ls_sort-subtot = &2.
append ls_sort to lt_sort.
END-OF-DEFINITION.

DATA:
ls_fieldcat TYPE slis_fieldcat_alv,
lt_fieldcat TYPE slis_t_fieldcat_alv,
lt_sort TYPE slis_t_sortinfo_alv,
ls_sort TYPE slis_sortinfo_alv,
ls_layout TYPE slis_layout_alv.

m_fieldcat 'VKORG' '' '' <b>'X'</b>.
m_fieldcat 'KUNNR' '' '' <b>'X'</b>.
m_fieldcat 'VBELN' '' '' <b>''</b>.
m_fieldcat 'NETWR' 'X' 'WAERK' <b>''</b>.
m_fieldcat 'WAERK' '' '' <b>''</b>.

m_sort 'VKORG' 'X'. " Sort by vkorg and subtotal
m_sort 'KUNNR' 'X'. " Sort by kunnr and subtotal
m_sort 'VBELN' ''. " Sort by vbeln

ls_layout-cell_merge = 'X'.
ls_layout-totals_before_items = 'X'.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
is_layout = ls_layout
it_fieldcat = lt_fieldcat
it_sort = lt_sort
TABLES
t_outtab = gt_vbak.

ENDFORM. " F_DISPLAY_DATA
***************** END OF PROGRAM Z_DEMO_ALV_SORT **********************

Add a comment
10|10000 characters needed characters exceeded

Assigned Tags

Related questions

6 Answers

  • Best Answer
    Posted on Oct 17, 2005 at 12:17 PM

    Hi Vladamir,

    Here is the description of the attribute TECH of the field catalogue.

    "<i>If this field is set, the relevant field is not displayed on the list and cannot be shown interactively. The field is only known in the field catalog. (For example, it must not be specified as a sorting criterion).</i>"

    That is the reason why your sum is not working when you add this field. What is it that you are trying to achieve using this attribute? As I see it, you should actually be using CFIELDNAME or CURRENCY along with NETWR to show the output with the correct decimal places based on currency.

    Please reward and close if answered.

    Srinivas

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 17, 2005 at 08:04 AM

    Hello!

    When i add bold text to this program. Total and subtotal texts disappear at first display. It appears only if you make a drill-down action.

    What could it be?

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 17, 2005 at 08:05 AM

    And? Your question is what?

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 17, 2005 at 08:06 AM
    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 17, 2005 at 08:19 AM

    Hi Buddy

    Please use LIST instead of GRID FM. It will work

    Add a comment
    10|10000 characters needed characters exceeded

  • Posted on Oct 17, 2005 at 08:21 AM

    The FM Name is REUSE_ALV_LIST_DISPLAY

    Add a comment
    10|10000 characters needed characters exceeded

Before answering

You should only submit an answer when you are proposing a solution to the poster's problem. If you want the poster to clarify the question or provide more information, please leave a comment instead, requesting additional details. When answering, please include specifics, such as step-by-step instructions, context for the solution, and links to useful resources. Also, please make sure that you answer complies with our Rules of Engagement.
You must be Logged in to submit an answer.

Up to 10 attachments (including images) can be used with a maximum of 1.0 MB each and 10.5 MB total.